[ObjC ARC] Converts ios/chrome/browser/ui/omnibox:omnibox_internal to ARC.

ios/chrome/browser/ui/omnibox/omnibox_text_field_ios.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/omnibox/omnibox_text_field_ios.h"
 
 #import <CoreText/CoreText.h>
 
 #include "base/command_line.h"
 #include "base/logging.h"
 #include "base/mac/foundation_util.h"
-#include "base/mac/objc_property_releaser.h"
-#include "base/mac/scoped_nsobject.h"
+
 #include "base/strings/sys_string_conversions.h"
 #include "components/grit/components_scaled_resources.h"
 #include "components/omnibox/browser/autocomplete_input.h"
 #include "ios/chrome/browser/autocomplete/autocomplete_scheme_classifier_impl.h"
 #import "ios/chrome/browser/ui/animation_util.h"
 #include "ios/chrome/browser/ui/omnibox/omnibox_util.h"
 #import "ios/chrome/browser/ui/reversed_animation.h"
 #include "ios/chrome/browser/ui/rtl_geometry.h"
 #include "ios/chrome/browser/ui/ui_util.h"
 #import "ios/chrome/browser/ui/uikit_ui_util.h"
 #import "ios/chrome/common/material_timing.h"
 #include "ios/chrome/grit/ios_strings.h"
 #include "ios/chrome/grit/ios_theme_resources.h"
 #include "skia/ext/skia_utils_ios.h"
 #include "third_party/google_toolbox_for_mac/src/iPhone/GTMFadeTruncatingLabel.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 #include "ui/gfx/color_palette.h"
 #include "ui/gfx/image/image.h"
 #import "ui/gfx/ios/NSString+CrStringDrawing.h"
 #include "ui/gfx/scoped_cg_context_save_gstate_mac.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 const CGFloat kFontSize = 16;
 const CGFloat kEditingRectX = 16;
 const CGFloat kEditingRectWidthInset = 10;
 const CGFloat kTextInset = 8;
 const CGFloat kTextInsetWithChip = 3;
 const CGFloat kTextInsetNoLeftView = 12;
 const CGFloat kImageInset = 9;
 const CGFloat kClearButtonRightMarginIphone = 7;
 const CGFloat kClearButtonRightMarginIpad = 12;
@@ skipping 40 matching lines @@
 // conversion from NSString to base::string16 if possible.
 - (NSString*)nsDisplayedText;
 
 @end
 
 #pragma mark -
 #pragma mark OmniboxTextFieldIOS
 
 @implementation OmniboxTextFieldIOS {
   // Currently selected chip text. Nil if no chip.
-  base::scoped_nsobject<NSString> _chipText;
-  base::scoped_nsobject<UILabel> _selection;
-  base::scoped_nsobject<UILabel> _preEditStaticLabel;
-  NSString* _preEditText;
-  base::scoped_nsobject<UIFont> _font;
-  base::scoped_nsobject<UIColor> _displayedTextColor;
-  base::scoped_nsobject<UIColor> _displayedTintColor;
-  UIColor* _selectedTextBackgroundColor;
-  UIColor* _placeholderTextColor;
+  NSString* _chipText;
+  UILabel* _selection;
+  UILabel* _preEditStaticLabel;
+  UIFont* _font;
+  UIColor* _displayedTextColor;
+  UIColor* _displayedTintColor;
 
   // The 'Copy URL' menu item is sometimes shown in the edit menu, so keep it
   // around to make adding/removing easier.
-  base::scoped_nsobject<UIMenuItem> _copyUrlMenuItem;
-
-  base::mac::ObjCPropertyReleaser _propertyReleaser_OmniboxTextFieldIOS;
+  UIMenuItem* _copyUrlMenuItem;
 }
 
 @synthesize leftViewImageId = _leftViewImageId;
 @synthesize preEditText = _preEditText;
 @synthesize clearingPreEditText = _clearingPreEditText;
 @synthesize selectedTextBackgroundColor = _selectedTextBackgroundColor;
 @synthesize placeholderTextColor = _placeholderTextColor;
 @synthesize incognito = _incognito;
 
 // Overload to allow for code-based initialization.
 - (instancetype)initWithFrame:(CGRect)frame {
   return [self initWithFrame:frame
                         font:[UIFont systemFontOfSize:kFontSize]
                    textColor:TextColor()
                    tintColor:nil];
 }
 
 - (instancetype)initWithFrame:(CGRect)frame
                          font:(UIFont*)font
                     textColor:(UIColor*)textColor
                     tintColor:(UIColor*)tintColor {
   self = [super initWithFrame:frame];
   if (self) {
-    _propertyReleaser_OmniboxTextFieldIOS.Init(self,
-                                               [OmniboxTextFieldIOS class]);
-    _font.reset([font retain]);
-    _displayedTextColor.reset([textColor retain]);
+    _font = font;
+    _displayedTextColor = textColor;
     if (tintColor) {
       [self setTintColor:tintColor];
-      _displayedTintColor.reset([tintColor retain]);
+      _displayedTintColor = tintColor;
     } else {
-      _displayedTintColor.reset([self.tintColor retain]);
+      _displayedTintColor = self.tintColor;
     }
     [self setFont:_font];
     [self setTextColor:_displayedTextColor];
     [self setClearButtonMode:UITextFieldViewModeNever];
     [self setRightViewMode:UITextFieldViewModeAlways];
     [self setAutocorrectionType:UITextAutocorrectionTypeNo];
     [self setAutocapitalizationType:UITextAutocapitalizationTypeNone];
     [self setEnablesReturnKeyAutomatically:YES];
     [self setReturnKeyType:UIReturnKeyGo];
     [self setContentVerticalAlignment:UIControlContentVerticalAlignmentCenter];
@@ skipping 51 matching lines @@
 }
 
 // Method called when the users touches the text input. This will accept the
 // autocompleted text.
 - (void)touchesBegan:(NSSet*)touches withEvent:(UIEvent*)event {
   if ([self isPreEditing]) {
     [self exitPreEditState];
     [super selectAll:nil];
   }
 
-  if (!_selection.get()) {
+  if (!_selection) {
     [super touchesBegan:touches withEvent:event];
     return;
   }
 
   // Only consider a single touch.
   UITouch* touch = [touches anyObject];
   if (!touch)
     return;
 
   // Accept selection.
-  base::scoped_nsobject<NSString> newText([[self nsDisplayedText] copy]);
+  NSString* newText = [[self nsDisplayedText] copy];
   [self clearAutocompleteText];
   [self setText:newText];
 }
 
 // Gets the bounds of the rect covering the URL.
 - (CGRect)preEditLabelRectForBounds:(CGRect)bounds {
   return [self editingRectForBounds:self.bounds];
 }
 
 // Creates a UILabel based on the current dimension of the text field and
 // displays the URL in the UILabel so it appears properly aligned to the URL.
 - (void)enterPreEditState {
   // Empty omnibox should show the insertion point immediately. There is
   // nothing to erase.
   if (!self.text.length || UIAccessibilityIsVoiceOverRunning())
     return;
 
   // Remembers the initial text input to compute the diff of what was there
   // and what was typed.
   [self setPreEditText:self.text];
 
   // Adjusts the placement so static URL lines up perfectly with UITextField.
-  DCHECK(!_preEditStaticLabel.get());
+  DCHECK(!_preEditStaticLabel);
   CGRect rect = [self preEditLabelRectForBounds:self.bounds];
-  _preEditStaticLabel.reset([[UILabel alloc] initWithFrame:rect]);
-  _preEditStaticLabel.get().backgroundColor = [UIColor clearColor];
-  _preEditStaticLabel.get().opaque = YES;
-  _preEditStaticLabel.get().font = _font;
-  _preEditStaticLabel.get().textColor = _displayedTextColor;
-  _preEditStaticLabel.get().lineBreakMode = NSLineBreakByTruncatingHead;
+  _preEditStaticLabel = [[UILabel alloc] initWithFrame:rect];
+  _preEditStaticLabel.backgroundColor = [UIColor clearColor];
+  _preEditStaticLabel.opaque = YES;
+  _preEditStaticLabel.font = _font;
+  _preEditStaticLabel.textColor = _displayedTextColor;
+  _preEditStaticLabel.lineBreakMode = NSLineBreakByTruncatingHead;
 
   NSDictionary* attributes =
       @{NSBackgroundColorAttributeName : [self selectedTextBackgroundColor]};
-  base::scoped_nsobject<NSAttributedString> preEditString(
+  NSAttributedString* preEditString =
       [[NSAttributedString alloc] initWithString:self.text
-                                      attributes:attributes]);
+                                      attributes:attributes];
   [_preEditStaticLabel setAttributedText:preEditString];
-  _preEditStaticLabel.get().textAlignment = [self preEditTextAlignment];
+  _preEditStaticLabel.textAlignment = [self preEditTextAlignment];
   [self addSubview:_preEditStaticLabel];
 }
 
 - (NSTextAlignment)bestAlignmentForText:(NSString*)text {
   if (text.length) {
     NSString* lang = CFBridgingRelease(CFStringTokenizerCopyBestStringLanguage(
         (CFStringRef)text, CFRangeMake(0, text.length)));
 
     if ([NSLocale characterDirectionForLanguage:lang] ==
         NSLocaleLanguageDirectionRightToLeft) {
       return NSTextAlignmentRight;
     }
   }
   return NSTextAlignmentLeft;
 }
 
 - (NSTextAlignment)bestTextAlignment {
   if ([self isFirstResponder]) {
     return [self bestAlignmentForText:[self text]];
   }
   return NSTextAlignmentNatural;
 }
 
 - (NSTextAlignment)preEditTextAlignment {
   // If the pre-edit text is wider than the omnibox, right-align the text so it
   // ends at the same x coord as the blue selection box.
   CGSize textSize =
-      [_preEditStaticLabel.get().text cr_pixelAlignedSizeWithFont:_font];
+      [_preEditStaticLabel.text cr_pixelAlignedSizeWithFont:_font];
   BOOL isLTR = [self bestTextAlignment] == NSTextAlignmentLeft;
-  return textSize.width < _preEditStaticLabel.get().frame.size.width
+  return textSize.width < _preEditStaticLabel.frame.size.width
              ? (isLTR ? NSTextAlignmentLeft : NSTextAlignmentRight)
              : (isLTR ? NSTextAlignmentRight : NSTextAlignmentLeft);
 }
 
 - (void)layoutSubviews {
   [super layoutSubviews];
   if ([self isPreEditing]) {
     CGRect rect = [self preEditLabelRectForBounds:self.bounds];
     [_preEditStaticLabel setFrame:rect];
 
     // Update text alignment since the pre-edit label's frame changed.
-    _preEditStaticLabel.get().textAlignment = [self preEditTextAlignment];
+    _preEditStaticLabel.textAlignment = [self preEditTextAlignment];
     [self hideTextAndCursor];
   } else if (!_selection) {
     [self showTextAndCursor];
   }
 }
 
 // Finishes pre-edit state by removing the UILabel with the URL.
 - (void)exitPreEditState {
   [self setPreEditText:nil];
   if (_preEditStaticLabel) {
     [_preEditStaticLabel removeFromSuperview];
-    _preEditStaticLabel.reset(nil);
+    _preEditStaticLabel = nil;
     [self showTextAndCursor];
   }
 }
 
 - (UIColor*)displayedTextColor {
   return _displayedTextColor;
 }
 
 // Returns whether we are processing the first touch event on the text field.
 - (BOOL)isPreEditing {
   return !![self preEditText];
 }
 
 - (void)enableLeftViewButton:(BOOL)isEnabled {
   if ([self leftView])
     [(UIButton*)[self leftView] setEnabled:isEnabled];
 }
 
 - (NSString*)nsDisplayedText {
-  if (_selection.get())
+  if (_selection)
     return [_selection text];
   return [self text];
 }
 
 - (base::string16)displayedText {
   return base::SysNSStringToUTF16([self nsDisplayedText]);
 }
 
 - (base::string16)autocompleteText {
   DCHECK_LT([[self text] length], [[_selection text] length])
       << "[_selection text] and [self text] are out of sync. "
       << "Please email justincohen@ and rohitrao@ if you see this.";
-  if (_selection.get() && [[_selection text] length] > [[self text] length]) {
+  if (_selection && [[_selection text] length] > [[self text] length]) {
     return base::SysNSStringToUTF16(
         [[_selection text] substringFromIndex:[[self text] length]]);
   }
   return base::string16();
 }
 
 - (void)select:(id)sender {
   if ([self isPreEditing]) {
     [self exitPreEditState];
   }
   [super select:sender];
 }
 
 - (void)selectAll:(id)sender {
   if ([self isPreEditing]) {
     [self exitPreEditState];
   }
-  if (_selection.get()) {
-    base::scoped_nsobject<NSString> newText([[self nsDisplayedText] copy]);
+  if (_selection) {
+    NSString* newText = [[self nsDisplayedText] copy];
     [self clearAutocompleteText];
     [self setText:newText];
   }
   [super selectAll:sender];
 }
 
 // Creates the SelectedTextLabel if it doesn't already exist and adds it as a
 // subview.
 - (void)createSelectionViewIfNecessary {
-  if (_selection.get())
+  if (_selection)
     return;
 
-  _selection.reset([[UILabel alloc] initWithFrame:CGRectZero]);
+  _selection = [[UILabel alloc] initWithFrame:CGRectZero];
   [_selection setFont:_font];
   [_selection setTextColor:_displayedTextColor];
   [_selection setOpaque:NO];
   [_selection setBackgroundColor:[UIColor clearColor]];
   [self addSubview:_selection];
   [self hideTextAndCursor];
 }
 
 - (BOOL)isShowingQueryRefinementChip {
   return (_chipText && ([self isFirstResponder] || [self isPreEditing]));
 }
 
 - (void)updateLeftView {
   const CGFloat kChipTextTopInset = 3.0;
   const CGFloat kChipTextLeftInset = 3.0;
 
   UIButton* leftViewButton = (UIButton*)self.leftView;
   // Only set the chip image if the omnibox is in focus.
   if ([self isShowingQueryRefinementChip]) {
     [leftViewButton setTitle:_chipText forState:UIControlStateNormal];
     [leftViewButton setImage:nil forState:UIControlStateNormal];
     [leftViewButton
         setTitleEdgeInsets:UIEdgeInsetsMake(kChipTextTopInset,
                                             kChipTextLeftInset, 0, 0)];
     // For iPhone, the left view is only updated when not in editing mode (i.e.
     // the text field is not first responder).
   } else if (_leftViewImageId && (IsIPadIdiom() || ![self isFirstResponder])) {
     UIImage* image = [NativeImage(_leftViewImageId)
         imageWithRenderingMode:UIImageRenderingModeAlwaysTemplate];
-    UIImageView* imageView =
-        [[[UIImageView alloc] initWithImage:image] autorelease];
+    UIImageView* imageView = [[UIImageView alloc] initWithImage:image];
     [leftViewButton setImage:imageView.image forState:UIControlStateNormal];
     [leftViewButton setTitle:nil forState:UIControlStateNormal];
     UIColor* tint = [UIColor whiteColor];
     if (!_incognito) {
       switch (_leftViewImageId) {
         case IDR_IOS_LOCATION_BAR_HTTP:
           tint = [UIColor darkGrayColor];
           break;
         case IDR_IOS_OMNIBOX_HTTPS_VALID:
           tint = skia::UIColorFromSkColor(gfx::kGoogleGreen700);
@@ skipping 45 matching lines @@
   // Extract substrings for the permanent text and the autocomplete text.  The
   // former needs to retain any text attributes from the original string.
   NSRange fieldRange = NSMakeRange(0, [text length] - autocompleteLength);
   NSAttributedString* fieldText =
       [text attributedSubstringFromRange:fieldRange];
 
   if (autocompleteLength > 0) {
     // Creating |autocompleteText| from |[text string]| has the added bonus of
     // removing all the previously set attributes. This way the autocomplete
     // text doesn't have a highlighted protocol, etc.
-    base::scoped_nsobject<NSMutableAttributedString> autocompleteText(
-        [[NSMutableAttributedString alloc] initWithString:[text string]]);
+    NSMutableAttributedString* autocompleteText =
+        [[NSMutableAttributedString alloc] initWithString:[text string]];
 
     [self createSelectionViewIfNecessary];
-    DCHECK(_selection.get());
+    DCHECK(_selection);
     [autocompleteText
         addAttribute:NSBackgroundColorAttributeName
                value:[self selectedTextBackgroundColor]
                range:NSMakeRange([fieldText length], autocompleteLength)];
     [_selection setAttributedText:autocompleteText];
     [_selection setTextAlignment:[self bestTextAlignment]];
   } else {
     [self clearAutocompleteText];
   }
 
@@ skipping 12 matching lines @@
 - (UIColor*)selectedTextBackgroundColor {
   return _selectedTextBackgroundColor ? _selectedTextBackgroundColor
                                       : [UIColor colorWithRed:204.0 / 255
                                                         green:221.0 / 255
                                                          blue:237.0 / 255
                                                         alpha:1.0];
 }
 
 // Ensures that attributedText always uses the proper style attributes.
 - (void)setAttributedText:(NSAttributedString*)attributedText {
-  base::scoped_nsobject<NSMutableAttributedString> mutableText(
-      [attributedText mutableCopy]);
+  NSMutableAttributedString* mutableText = [attributedText mutableCopy];
   NSRange entireString = NSMakeRange(0, [mutableText length]);
 
   // Set the font.
   [mutableText addAttribute:NSFontAttributeName value:_font range:entireString];
 
   // When editing, use the default text color for all text.
   if (self.editing) {
     // Hide the text when the |_selection| label is displayed.
     UIColor* textColor =
-        _selection ? [UIColor clearColor] : _displayedTextColor.get();
+        _selection ? [UIColor clearColor] : _displayedTextColor;
     [mutableText addAttribute:NSForegroundColorAttributeName
                         value:textColor
                         range:entireString];
   } else {
-    base::scoped_nsobject<NSMutableParagraphStyle> style(
-        [[NSMutableParagraphStyle alloc] init]);
+    NSMutableParagraphStyle* style = [[NSMutableParagraphStyle alloc] init];
     // URLs have their text direction set to to LTR (avoids RTL characters
     // making the URL render from right to left, as per RFC 3987 Section 4.1).
     [style setBaseWritingDirection:NSWritingDirectionLeftToRight];
 
     // Set linebreak mode to 'clipping' to ensure the text is never elided.
     // This is a workaround for iOS 6, where it appears that
     // [self.attributedText size] is not wide enough for the string (e.g. a URL
     // else ending with '.com' will be elided to end with '.c...'). It appears
     // to be off by one point so clipping is acceptable as it doesn't actually
     // cut off any of the text.
@@ skipping 29 matching lines @@
                                   textRangeFromPosition:[self
                                                             beginningOfDocument]
                                              toPosition:[self endOfDocument]]];
 }
 
 - (void)setPlaceholder:(NSString*)placeholder {
   if (placeholder && _placeholderTextColor) {
     NSDictionary* attributes =
         @{NSForegroundColorAttributeName : _placeholderTextColor};
     self.attributedPlaceholder =
-        [[[NSAttributedString alloc] initWithString:placeholder
-                                         attributes:attributes] autorelease];
+        [[NSAttributedString alloc] initWithString:placeholder
+                                        attributes:attributes];
   } else {
     [super setPlaceholder:placeholder];
   }
 }
 
 - (void)setText:(NSString*)text {
-  NSAttributedString* as =
-      [[[NSAttributedString alloc] initWithString:text] autorelease];
+  NSAttributedString* as = [[NSAttributedString alloc] initWithString:text];
   if (self.text.length > 0 && as.length == 0) {
     // Remove the fade animations before the subviews are removed.
     [self cleanUpFadeAnimations];
   }
   [self setTextInternal:as autocompleteLength:0];
 }
 
 - (void)setText:(NSAttributedString*)text
     userTextLength:(size_t)userTextLength {
   DCHECK_LE(userTextLength, [text length]);
 
   NSUInteger autocompleteLength = [text length] - userTextLength;
   [self setTextInternal:text autocompleteLength:autocompleteLength];
 }
 
 - (void)setChipText:(NSString*)chipName {
-  _chipText.reset();
+  _chipText = nil;
   if ([chipName length]) {
     if ([self bestAlignmentForText:chipName] == NSTextAlignmentLeft)
       chipName = [chipName stringByAppendingString:@":"];
-    _chipText.reset([chipName copy]);
+    _chipText = [chipName copy];
   }
   [self updateLeftView];
 }
 
 - (BOOL)hasAutocompleteText {
-  return !!_selection.get();
+  return !!_selection;
 }
 
 - (void)clearAutocompleteText {
   if (_selection) {
     [_selection removeFromSuperview];
-    _selection.reset(nil);
+    _selection = nil;
     [self showTextAndCursor];
   }
 }
 
 - (BOOL)isColorHidden:(UIColor*)color {
   return ([color isEqual:[UIColor clearColor]] ||
           CGColorGetAlpha(color.CGColor) < 0.05);
 }
 
 // Set the text field's text and cursor to their displayed colors. To be called
@@ skipping 350 matching lines @@
       [self offsetFromPosition:beginning toPosition:[selectedRange start]];
   NSInteger length = [self offsetFromPosition:[selectedRange start]
                                    toPosition:[selectedRange end]];
   return NSMakeRange(start, length);
 }
 
 - (BOOL)becomeFirstResponder {
   if (![super becomeFirstResponder])
     return NO;
 
-  if (!_copyUrlMenuItem.get()) {
+  if (!_copyUrlMenuItem) {
     NSString* const kTitle = l10n_util::GetNSString(IDS_IOS_COPY_URL);
-    _copyUrlMenuItem.reset(
-        [[UIMenuItem alloc] initWithTitle:kTitle action:@selector(copyUrl:)]);
+    _copyUrlMenuItem =
+        [[UIMenuItem alloc] initWithTitle:kTitle action:@selector(copyUrl:)];
   }
 
   // Add the "Copy URL" menu item to the |sharedMenuController| if necessary.
   UIMenuController* menuController = [UIMenuController sharedMenuController];
   if (menuController.menuItems) {
     if (![menuController.menuItems containsObject:_copyUrlMenuItem]) {
       menuController.menuItems =
           [menuController.menuItems arrayByAddingObject:_copyUrlMenuItem];
     }
   } else {
@@ skipping 33 matching lines @@
   // Disable the RTL arrow menu item. The omnibox sets alignment based on the
   // text in the field, and should not be overridden.
   if ([NSStringFromSelector(action) hasPrefix:@"makeTextWritingDirection"]) {
     return NO;
   }
 
   return [super canPerformAction:action withSender:sender];
 }
 
 @end