CoreAnimation: Reduce VA usage by extra layers

chrome/browser/ui/cocoa/tab_contents/tab_contents_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/tab_contents/tab_contents_controller.h"
 
 #include <utility>
 
+#include "base/command_line.h"
+#include "base/mac/scoped_cftyperef.h"
 #include "base/mac/scoped_nsobject.h"
 #include "chrome/browser/devtools/devtools_window.h"
 #import "chrome/browser/themes/theme_properties.h"
 #import "chrome/browser/themes/theme_service.h"
 #import "chrome/browser/ui/cocoa/themed_window.h"
 #include "content/public/browser/render_view_host.h"
 #include "content/public/browser/render_widget_host_view.h"
 #include "content/public/browser/web_contents.h"
 #include "content/public/browser/web_contents_observer.h"
 #include "content/public/browser/web_contents_view.h"
+#include "ui/base/cocoa/animation_utils.h"
+#include "ui/base/ui_base_switches.h"
 #include "ui/gfx/geometry/rect.h"
 
 using content::WebContents;
 using content::WebContentsObserver;
 
 // FullscreenObserver is used by TabContentsController to monitor for the
 // showing/destruction of fullscreen render widgets.  When notified,
 // TabContentsController will alter its child view hierarchy to either embed a
 // fullscreen render widget view or restore the normal WebContentsView render
 // view.  The embedded fullscreen render widget will fill the user's screen in
@@ skipping 25 matching lines @@
     [controller_ toggleFullscreenWidget:YES];
   }
 
  private:
   TabContentsController* const controller_;
 
   DISALLOW_COPY_AND_ASSIGN(FullscreenObserver);
 };
 
 @interface TabContentsController (TabContentsContainerViewDelegate)
+- (BOOL)contentsInFullscreenCaptureMode;
 // Computes and returns the frame to use for the contents view within the
 // container view.
 - (NSRect)frameForContentsView;
 @end
 
 // An NSView with special-case handling for when the contents view does not
 // expand to fill the entire tab contents area. See 'AutoEmbedFullscreen mode'
 // in header file comments.
 @interface TabContentsContainerView : NSView {
  @private
   TabContentsController* delegate_;  // weak
 }
+
+- (NSColor*)computeBackgroundColor;
 @end
 
 @implementation TabContentsContainerView
 
 - (id)initWithDelegate:(TabContentsController*)delegate {
   if ((self = [super initWithFrame:NSZeroRect])) {
     delegate_ = delegate;
+    if (!CommandLine::ForCurrentProcess()->HasSwitch(
+            switches::kDisableCoreAnimation)) {
+      ScopedCAActionDisabler disabler;
+      base::scoped_nsobject<CALayer> layer([[CALayer alloc] init]);
+      [layer setBackgroundColor:CGColorGetConstantColor(kCGColorWhite)];
+      [self setLayer:layer];
+      [self setWantsLayer:YES];
+    }
   }
   return self;
 }
 
 // Called by the delegate during dealloc to invalidate the pointer held by this
 // view.
 - (void)delegateDestroyed {
   delegate_ = nil;
 }
 
+- (NSColor*)computeBackgroundColor {
+  // This view is sometimes flashed into visibility (e.g, when closing
+  // windows), so ensure that the flash be white in those cases.
+  if (![delegate_ contentsInFullscreenCaptureMode])
+    return [NSColor whiteColor];
+
+  // Fill with a dark tint of the new tab page's background color.  This is
+  // only seen when the subview is sized specially for fullscreen tab capture.
+  NSColor* bgColor = nil;
+  ThemeService* const theme =
+      static_cast<ThemeService*>([[self window] themeProvider]);
+  if (theme)
+    bgColor = theme->GetNSColor(ThemeProperties::COLOR_NTP_BACKGROUND);
+  if (!bgColor)
+    bgColor = [[self window] backgroundColor];
+  const float kDarknessFraction = 0.80f;
+  return [bgColor blendedColorWithFraction:kDarknessFraction
+                                   ofColor:[NSColor blackColor]];
+}
+
 // Override -drawRect to fill the view with a solid color outside of the
 // subview's frame.
 - (void)drawRect:(NSRect)dirtyRect {
   NSView* const contentsView =
       [[self subviews] count] > 0 ? [[self subviews] objectAtIndex:0] : nil;
   if (!contentsView || !NSContainsRect([contentsView frame], dirtyRect)) {
-    // Fill with a dark tint of the new tab page's background color.  This is
-    // only seen when the subview is sized specially for fullscreen tab capture.
-    NSColor* bgColor = nil;
-    ThemeService* const theme =
-        static_cast<ThemeService*>([[self window] themeProvider]);
-    if (theme)
-      bgColor = theme->GetNSColor(ThemeProperties::COLOR_NTP_BACKGROUND);
-    if (!bgColor)
-      bgColor = [[self window] backgroundColor];
-    const float kDarknessFraction = 0.80f;
-    [[bgColor blendedColorWithFraction:kDarknessFraction
-                               ofColor:[NSColor blackColor]] setFill];
+    [[self computeBackgroundColor] setFill];
     NSRectFill(dirtyRect);
   }
   [super drawRect:dirtyRect];
 }
 
 // Override auto-resizing logic to query the delegate for the exact frame to
 // use for the contents view.
 - (void)resizeSubviewsWithOldSize:(NSSize)oldBoundsSize {
   NSView* const contentsView =
       [[self subviews] count] > 0 ? [[self subviews] objectAtIndex:0] : nil;
   if (!contentsView || [contentsView autoresizingMask] == NSViewNotSizable ||
       !delegate_) {
     return;
   }
   [contentsView setFrame:[delegate_ frameForContentsView]];
 }
 
+// Update the background layer's color whenever the view needs to repaint.
+- (void)setNeedsDisplayInRect:(NSRect)rect {
+  [super setNeedsDisplayInRect:rect];
+
+  // Convert from an NSColor to a CGColorRef.
+  NSColor* nsBackgroundColor = [self computeBackgroundColor];
+  NSColorSpace* nsColorSpace = [nsBackgroundColor colorSpace];
+  CGColorSpaceRef cgColorSpace = [nsColorSpace CGColorSpace];
+  const NSInteger numberOfComponents = [nsBackgroundColor numberOfComponents];
+  CGFloat components[numberOfComponents];
+  [nsBackgroundColor getComponents:components];
+  base::ScopedCFTypeRef<CGColorRef> cgBackgroundColor(
+      CGColorCreate(cgColorSpace, components));
+
+  ScopedCAActionDisabler disabler;
+  [[self layer] setBackgroundColor:cgBackgroundColor];
+}
+
 @end  // @implementation TabContentsContainerView
 
 @implementation TabContentsController
 @synthesize webContents = contents_;
 
 - (id)initWithContents:(WebContents*)contents
     andAutoEmbedFullscreen:(BOOL)enableEmbeddedFullscreen {
   if ((self = [super initWithNibName:nil bundle:nil])) {
     if (enableEmbeddedFullscreen)
       fullscreenObserver_.reset(new FullscreenObserver(self));
@@ skipping 118 matching lines @@
     [self ensureContentsVisible];
   }
 }
 
 - (void)toggleFullscreenWidget:(BOOL)enterFullscreen {
   isEmbeddingFullscreenWidget_ = enterFullscreen &&
       contents_ && contents_->GetFullscreenRenderWidgetHostView();
   [self ensureContentsVisible];
 }
 
-- (NSRect)frameForContentsView {
-  const NSSize containerSize = [[self view] frame].size;
-  gfx::Rect rect;
-  rect.set_width(containerSize.width);
-  rect.set_height(containerSize.height);
-
-  // In most cases, the contents view is simply sized to fill the container
-  // view's bounds. Only WebContentses that are in fullscreen mode and being
-  // screen-captured will engage the special layout/sizing behavior.
+- (BOOL)contentsInFullscreenCaptureMode {
   if (!fullscreenObserver_)
-    return NSRectFromCGRect(rect.ToCGRect());
+    return NO;
   // Note: Grab a known-valid WebContents pointer from |fullscreenObserver_|.
   content::WebContents* const wc = fullscreenObserver_->web_contents();
   if (!wc ||
       wc->GetCapturerCount() == 0 ||
       wc->GetPreferredSize().IsEmpty() ||
       !(isEmbeddingFullscreenWidget_ ||
         (wc->GetDelegate() &&
          wc->GetDelegate()->IsFullscreenForTabOrPending(wc)))) {
+    return NO;
+  }
+  return YES;
+}
+
+- (NSRect)frameForContentsView {
+  const NSSize containerSize = [[self view] frame].size;
+  gfx::Rect rect;
+  rect.set_width(containerSize.width);
+  rect.set_height(containerSize.height);
+
+  // In most cases, the contents view is simply sized to fill the container
+  // view's bounds. Only WebContentses that are in fullscreen mode and being
+  // screen-captured will engage the special layout/sizing behavior.
+  if (![self contentsInFullscreenCaptureMode])
     return NSRectFromCGRect(rect.ToCGRect());
-  }
 
   // Size the contents view to the capture video resolution and center it. If
   // the container view is not large enough to fit it at the preferred size,
   // scale down to fit (preserving aspect ratio).
+  content::WebContents* const wc = fullscreenObserver_->web_contents();
   const gfx::Size captureSize = wc->GetPreferredSize();
   if (captureSize.width() <= rect.width() &&
       captureSize.height() <= rect.height()) {
     // No scaling, just centering.
     rect.ClampToCenteredSize(captureSize);
   } else {
     // Scale down, preserving aspect ratio, and center.
     // TODO(miu): This is basically media::ComputeLetterboxRegion(), and it
     // looks like others have written this code elsewhere.  Let's consolidate
     // into a shared function ui/gfx/geometry or around there.
     const int64 x = static_cast<int64>(captureSize.width()) * rect.height();
     const int64 y = static_cast<int64>(captureSize.height()) * rect.width();
     if (y < x) {
       rect.ClampToCenteredSize(gfx::Size(
           rect.width(), static_cast<int>(y / captureSize.width())));
     } else {
       rect.ClampToCenteredSize(gfx::Size(
           static_cast<int>(x / captureSize.height()), rect.height()));
     }
   }
 
   return NSRectFromCGRect(rect.ToCGRect());
 }
 
 @end