[Mac] Have BaseBubbleController dismiss bubbles when they would lose key state on 10.8.

chrome/browser/ui/cocoa/base_bubble_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/base_bubble_controller.h"
 
 #include "base/logging.h"
 #include "base/mac/bundle_locations.h"
+#include "base/mac/closure_blocks_leopard_compat.h"
 #include "base/mac/mac_util.h"
 #include "base/memory/scoped_nsobject.h"
 #include "base/string_util.h"
 #import "chrome/browser/ui/cocoa/info_bubble_view.h"
 #include "content/public/browser/notification_observer.h"
 #include "content/public/browser/notification_registrar.h"
 #include "content/public/browser/notification_service.h"
 #include "content/public/browser/notification_types.h"
 #include "grit/generated_resources.h"
 #include "ui/base/l10n/l10n_util.h"
 
 @interface BaseBubbleController (Private)
 - (void)updateOriginFromAnchor;
 @end
 
+#if !defined(MAC_OS_X_VERSION_10_6) || \
+    MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_6
+@interface NSEvent (SnowLeopardDeclarations)
++ (id)addLocalMonitorForEventsMatchingMask:(NSUInteger)mask
+                                   handler:(NSEvent* (^)(NSEvent*))block;
++ (void)removeMonitor:(id)eventMonitor;
+@end
+
+@interface NSOperationQueue (SnowLeopardDeclarations)
++ (id)mainQueue;
+@end
+
+@interface NSNotificationCenter (SnowLeopardDeclarations)
+- (id)addObserverForName:(NSString*)name
+                  object:(id)obj
+                   queue:(NSOperationQueue*)queue
+              usingBlock:(void (^)(NSNotification*))block;
+@end
+#endif  // MAC_OS_X_VERSION_10_6
+
 namespace BaseBubbleControllerInternal {
 
 // This bridge listens for notifications so that the bubble closes when a user
 // switches tabs (including by opening a new one).
 class Bridge : public content::NotificationObserver {
  public:
   explicit Bridge(BaseBubbleController* controller) : controller_(controller) {
     registrar_.Add(this, content::NOTIFICATION_WEB_CONTENTS_HIDDEN,
         content::NotificationService::AllSources());
   }
@@ skipping 120 matching lines @@
   [self autorelease];
 }
 
 // We want this to be a child of a browser window.  addChildWindow:
 // (called from this function) will bring the window on-screen;
 // unfortunately, [NSWindowController showWindow:] will also bring it
 // on-screen (but will cause unexpected changes to the window's
 // position).  We cannot have an addChildWindow: and a subsequent
 // showWindow:. Thus, we have our own version.
 - (void)showWindow:(id)sender {
-  NSWindow* window = [self window];  // completes nib load
+  NSWindow* window = [self window];  // Completes nib load.
   [self updateOriginFromAnchor];
   [parentWindow_ addChildWindow:window ordered:NSWindowAbove];
   [window makeKeyAndOrderFront:self];
+  [self registerKeyStateEventTap];
 }
 
 - (void)close {
+  // The bubble will be closing, so remove the event taps.
+  if (eventTap_) {
+    [NSEvent removeMonitor:eventTap_];
+    eventTap_ = nil;
+  }
+  if (resignationObserver_) {
+    [[NSNotificationCenter defaultCenter]
+        removeObserver:resignationObserver_
+                  name:NSWindowDidResignKeyNotification
+                object:nil];
+    resignationObserver_ = nil;
+  }
+
   [[[self window] parentWindow] removeChildWindow:[self window]];
   [super close];
 }
 
 // The controller is the delegate of the window so it receives did resign key
 // notifications. When key is resigned mirror Windows behavior and close the
 // window.
 - (void)windowDidResignKey:(NSNotification*)notification {
   NSWindow* window = [self window];
   DCHECK_EQ([notification object], window);
   if ([window isVisible]) {
     // If the window isn't visible, it is already closed, and this notification
     // has been sent as part of the closing operation, so no need to close.
     [self close];
   }
 }
 
+// Since the bubble shares first responder with its parent window, set
+// event handlers to dismiss the bubble when it would normally lose key
+// state.
+- (void)registerKeyStateEventTap {
+  // Parent key state sharing is only avaiable on 10.7+.
+  if (!base::mac::IsOSLionOrLater())
+    return;
+
+  NSWindow* window = self.window;
+  NSNotification* note =
+      [NSNotification notificationWithName:NSWindowDidResignKeyNotification
+                                    object:window];
+
+  // The eventTap_ catches clicks within the application that are outside the
+  // window.
+  eventTap_ = [NSEvent
+      addLocalMonitorForEventsMatchingMask:NSLeftMouseDownMask
+      handler:^NSEvent* (NSEvent* event) {
+          if (event.window != window){
+            // Call via the runloop because this block is called in the
+            // middle of event dispatch.
+            [self performSelector:@selector(windowDidResignKey:)
+                       withObject:note
+                       afterDelay:0];
+          }
+          return event;
+      }];
+
+  // The resignationObserver_ watches for when a window resigns key state,
+  // meaning the key window has changed and the bubble should be dismissed.
+  NSNotificationCenter* center = [NSNotificationCenter defaultCenter];
+  resignationObserver_ =
+      [center addObserverForName:NSWindowDidResignKeyNotification
+                          object:nil
+                           queue:[NSOperationQueue mainQueue]
+                      usingBlock:^(NSNotification* notif) {
+                          [self windowDidResignKey:note];
+                      }];
+}
+
 // By implementing this, ESC causes the window to go away.
 - (IBAction)cancel:(id)sender {
   // This is not a "real" cancel as potential changes to the radio group are not
   // undone. That's ok.
   [self close];
 }
 
 // Takes the |anchor_| point and adjusts the window's origin accordingly.
 - (void)updateOriginFromAnchor {
   NSWindow* window = [self window];
@@ skipping 24 matching lines @@
 
     default:
       NOTREACHED();
   }
 
   origin.y -= NSHeight([window frame]);
   [window setFrameOrigin:origin];
 }
 
 @end  // BaseBubbleController