Update scoped_nsobject to be copyable.

base/memory/scoped_nsobject.h

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #ifndef BASE_MEMORY_SCOPED_NSOBJECT_H_
 #define BASE_MEMORY_SCOPED_NSOBJECT_H_
 #pragma once
 
 #import <Foundation/Foundation.h>
 #include "base/basictypes.h"
 #include "base/compiler_specific.h"
 
 // scoped_nsobject<> is patterned after scoped_ptr<>, but maintains ownership
 // of an NSObject subclass object.  Style deviations here are solely for
 // compatibility with scoped_ptr<>'s interface, with which everyone is already
 // familiar.
 //
-// When scoped_nsobject<> takes ownership of an object (in the constructor or
-// in reset()), it takes over the caller's existing ownership claim.  The
-// caller must own the object it gives to scoped_nsobject<>, and relinquishes
-// an ownership claim to that object.  scoped_nsobject<> does not call
-// -retain.
+// By default, scoped_nsobject<> takes ownership of an object (in the
+// constructor or in reset()), it takes over the caller's existing ownership

[Mark Mentovai, 2012/02/07 17:13:17]

Awkward phrasing. How ’bout

By default, scoped_nsobject<> takes ownership of an object (in the constructor
or in reset()) by taking over the caller's existing ownership claim.

[qsr, 2012/02/08 14:59:41]

Done.

+// claim.  The caller must own the object it gives to scoped_nsobject<>, and
+// relinquishes an ownership claim to that object.  scoped_nsobject<> does not
+// call -retain. This behavior is parametrized by the |OwnershipPolicy| enum.
+// If the value |RETAIN| is passed (in the constructor or in reset()), then
+// scoped_nsobject<> will call |retain| on the object, and the initial

[Mark Mentovai, 2012/02/07 17:13:17]

-retain instead of |retain|

[qsr, 2012/02/08 14:59:41]

Done.

+// ownsershop is not changed.

[Mark Mentovai, 2012/02/07 17:13:17]

ownership, not ownsershop.

[qsr, 2012/02/08 14:59:41]

Done.

+//
+// scoped_nsprotocol<> has the same behavior than scoped_nsobject, but can be
+// used with protocols.
 //
 // scoped_nsobject<> is not to be used for NSAutoreleasePools. For
 // NSAutoreleasePools use ScopedNSAutoreleasePool from
 // scoped_nsautorelease_pool.h instead.
 // We check for bad uses of scoped_nsobject and NSAutoreleasePool at compile
 // time with a template specialization (see below).
+
+enum OwnershipPolicy {
+  ACQUIRE,

[Mark Mentovai, 2012/02/07 17:13:17]

Can we stuff this into a namespace? Having ACQUIRE and RETAIN available at the
global scope seems like it’ll cause us to hit snags.

[qsr, 2012/02/08 14:59:41]

Done.

+  RETAIN
+};
+
 template<typename NST>
-class scoped_nsobject {
+class scoped_nsprotocol {
  public:
-  explicit scoped_nsobject(NST* object = nil)
-      : object_(object) {
+  scoped_nsprotocol(NST object = nil, OwnershipPolicy policy = ACQUIRE)
+      : object_(policy == ACQUIRE ? object : [object retain]) {

[Mark Mentovai, 2012/02/07 17:13:17]

Here and on line 62:

I can appreciate the terseness of how you’ve written it, but I wonder if it
would read more clearly in a “say what you mean” sense if you wrote the
assignment as object_(object) and then conditionally retained as a separate
statement. The idea here is that |object| should always be assigned into
|object_|, completely independent of what |policy| is. You and I both know that
-retain just returns its receiver, so the code you’ve written is fine, but it
sort of masks the actual intent.

[qsr, 2012/02/08 14:59:41]

Done.

   }
 
-  ~scoped_nsobject() {
+  explicit scoped_nsprotocol(const scoped_nsprotocol<NST>& other)

[Mark Mentovai, 2012/02/07 17:13:17]

I don’t think this will work in STL containers with the copy constructor marked
explicit.

[Mark Mentovai, 2012/02/07 17:13:17]

Here and on line 56:

The other methods in this class that operate on another scoped_nsprotocol<>
refer to the other one as |that| (lines 67 and 68). You should be consistent.

[qsr, 2012/02/08 14:59:41]

Done.

[qsr, 2012/02/08 14:59:41]

 You are right. The funny thing is this compiles perfectly right, but the
following:
scoped_nsobject<T> p1(foo);
scoped_nsobject<T> p2 = p1;

 will call the other constructor, with the default policy, which is exactly what
we do not want. To have all working correctly, I have to remove the explicit
from here, and add it to the first constructor. That allowed me to learn that
explicit can have a use on multi parameters constructor.

+      : object_([other.object_ retain]) {
+  }
+
+  ~scoped_nsprotocol() {
     [object_ release];
   }
 
-  void reset(NST* object = nil) {
-    // We intentionally do not check that object != object_ as the caller must
-    // already have an ownership claim over whatever it gives to
-    // scoped_nsobject and ScopedCFTypeRef, whether it's in the constructor or
-    // in a call to reset().  In either case, it relinquishes that claim and
-    // the scoper assumes it.
-    [object_ release];
-    object_ = object;
+  scoped_nsprotocol& operator= (const scoped_nsprotocol<NST>& other) {

[Mark Mentovai, 2012/02/07 17:13:17]

No space between operator= and the (.

[qsr, 2012/02/08 14:59:41]

Done.

+    reset(other.get(), RETAIN);
+    return *this;
   }
 
-  bool operator==(NST* that) const { return object_ == that; }
-  bool operator!=(NST* that) const { return object_ != that; }
+  void reset(NST object = nil, OwnershipPolicy policy = ACQUIRE) {
+    NST temp = policy == ACQUIRE ? object : [object retain];
+    [object_ release];
+    object_ = temp;
+  }
 
-  operator NST*() const {
+  bool operator==(NST that) const { return object_ == that; }
+  bool operator!=(NST that) const { return object_ != that; }
+
+  operator NST() const {
     return object_;
   }
 
-  NST* get() const {
+  NST get() const {
     return object_;
   }
 
-  void swap(scoped_nsobject& that) {
-    NST* temp = that.object_;
+  void swap(scoped_nsprotocol& that) {
+    NST temp = that.object_;
     that.object_ = object_;
     object_ = temp;
   }
 
-  // scoped_nsobject<>::release() is like scoped_ptr<>::release.  It is NOT
-  // a wrapper for [object_ release].  To force a scoped_nsobject<> object to
-  // call [object_ release], use scoped_nsobject<>::reset().
-  NST* release() WARN_UNUSED_RESULT {
-    NST* temp = object_;
+  // scoped_nsprotocol<>::release() is like scoped_ptr<>::release.  It is NOT a
+  // wrapper for [object_ release].  To force a scoped_nsprotocol<> call
+  // [object_ release], use scoped_nsprotocol<>::reset().
+  NST release() WARN_UNUSED_RESULT {
+    NST temp = object_;
     object_ = nil;
     return temp;
   }
 
  private:
-  NST* object_;
-
-  DISALLOW_COPY_AND_ASSIGN(scoped_nsobject);
+  NST object_;
 };
 
 // Free functions
 template <class C>
-void swap(scoped_nsobject<C>& p1, scoped_nsobject<C>& p2) {
+void swap(scoped_nsprotocol<C>& p1, scoped_nsprotocol<C>& p2) {
   p1.swap(p2);
 }
 
 template <class C>
-bool operator==(C* p1, const scoped_nsobject<C>& p2) {
+bool operator==(C p1, const scoped_nsprotocol<C>& p2) {
   return p1 == p2.get();
 }
 
 template <class C>
-bool operator!=(C* p1, const scoped_nsobject<C>& p2) {
+bool operator!=(C p1, const scoped_nsprotocol<C>& p2) {
   return p1 != p2.get();
 }
 
+template<typename NST>
+class scoped_nsobject : public scoped_nsprotocol<NST*> {
+ public:
+  scoped_nsobject(NST* object = nil, OwnershipPolicy policy = ACQUIRE)
+      : scoped_nsprotocol<NST*>(object, policy) {
+  }
+
+  explicit scoped_nsobject(const scoped_nsobject<NST>& other)

[Mark Mentovai, 2012/02/07 17:13:17]

The same comments as on line 48 applies here and on lines 124, 138, and 142.

[qsr, 2012/02/08 14:59:41]

Done.

+      : scoped_nsprotocol<NST*>(other) {
+  }
+
+  scoped_nsobject& operator= (const scoped_nsobject<NST>& other) {

[Mark Mentovai, 2012/02/07 17:13:17]

The same comment as on line 56 applies here and on line 142.

[qsr, 2012/02/08 14:59:41]

Done.

+    scoped_nsprotocol<NST*>::operator=(other);
+    return *this;
+  }
+};

[Mark Mentovai, 2012/02/07 17:13:17]

Do we need the “free functions” (lines 97-111) for scoped_nsobject too?
scoped_nsobject<id> as well?

[qsr, 2012/02/08 14:59:41]

 I might be missing something, but why would we need it? As scoped_nsobject are
scoped_nsprotocol by inheritance you can use all those free function on it. I'll
add that to the test.

 
 // Specialization to make scoped_nsobject<id> work.
 template<>
-class scoped_nsobject<id> {
+class scoped_nsobject<id> : public scoped_nsprotocol<id> {
  public:
-  explicit scoped_nsobject(id object = nil)
-      : object_(object) {
+  scoped_nsobject(id object = nil, OwnershipPolicy policy = ACQUIRE)
+      : scoped_nsprotocol<id>(object, policy) {
   }
 
-  ~scoped_nsobject() {
-    [object_ release];
+  explicit scoped_nsobject(const scoped_nsobject<id>& other)
+      : scoped_nsprotocol<id>(other) {
   }
 
-  void reset(id object = nil) {
-    // We intentionally do not check that object != object_ as the caller must
-    // already have an ownership claim over whatever it gives to
-    // scoped_nsobject and ScopedCFTypeRef, whether it's in the constructor or
-    // in a call to reset().  In either case, it relinquishes that claim and
-    // the scoper assumes it.
-    [object_ release];
-    object_ = object;
+  scoped_nsobject& operator= (const scoped_nsobject<id>& other) {
+    scoped_nsprotocol<id>::operator=(other);
+    return *this;
   }
-
-  bool operator==(id that) const { return object_ == that; }
-  bool operator!=(id that) const { return object_ != that; }
-
-  operator id() const {
-    return object_;
-  }
-
-  id get() const {
-    return object_;
-  }
-
-  void swap(scoped_nsobject& that) {
-    id temp = that.object_;
-    that.object_ = object_;
-    object_ = temp;
-  }
-
-  // scoped_nsobject<>::release() is like scoped_ptr<>::release.  It is NOT
-  // a wrapper for [object_ release].  To force a scoped_nsobject<> object to
-  // call [object_ release], use scoped_nsobject<>::reset().
-  id release() WARN_UNUSED_RESULT {
-    id temp = object_;
-    object_ = nil;
-    return temp;
-  }
-
- private:
-  id object_;
-
-  DISALLOW_COPY_AND_ASSIGN(scoped_nsobject);
 };
 
 // Do not use scoped_nsobject for NSAutoreleasePools, use
 // ScopedNSAutoreleasePool instead. This is a compile time check. See details
 // at top of header.
 template<>
 class scoped_nsobject<NSAutoreleasePool> {
  private:
-  explicit scoped_nsobject(NSAutoreleasePool* object = nil);
+  scoped_nsobject(NSAutoreleasePool* object = nil,
+                  OwnershipPolicy policy = ACQUIRE);
   DISALLOW_COPY_AND_ASSIGN(scoped_nsobject);
 };
-
-// Equivalent of scoped_nsobject for a id<protocol>. This is exactly the same
-// class as scoped_nsobject, except that it doesn't handle any pointer
-// transformation.
-template<typename NST>
-class scoped_nsprotocol {
- public:
-  explicit scoped_nsprotocol(NST object = nil) : object_(object) {
-  }
-
-  ~scoped_nsprotocol() {
-    [object_ release];
-  }
-
-  void reset(NST object = nil) {
-    [object_ release];
-    object_ = object;
-  }
-
-  bool operator==(NST that) const { return object_ == that; }
-  bool operator!=(NST that) const { return object_ != that; }
-
-  operator NST() const {
-    return object_;
-  }
-
-  NST get() const {
-    return object_;
-  }
-
-  void swap(scoped_nsprotocol& that) {
-    NST temp = that.object_;
-    that.object_ = object_;
-    object_ = temp;
-  }
-
-  NST release() WARN_UNUSED_RESULT {
-    NST temp = object_;
-    object_ = nil;
-    return temp;
-  }
-
- private:
-  NST object_;
-
-  DISALLOW_COPY_AND_ASSIGN(scoped_nsprotocol);
-};
-
-// Free functions
-template <class C>
-void swap(scoped_nsprotocol<C>& p1, scoped_nsprotocol<C>& p2) {
-  p1.swap(p2);
-}
-
-template <class C>
-bool operator==(C p1, const scoped_nsprotocol<C>& p2) {
-  return p1 == p2.get();
-}
-
-template <class C>
-bool operator!=(C p1, const scoped_nsprotocol<C>& p2) {
-  return p1 != p2.get();
-}
-
 #endif  // BASE_MEMORY_SCOPED_NSOBJECT_H_