Publish app shortcuts on Mac

base/mac/foundation_util.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "base/mac/foundation_util.h"
 
 #include <stdlib.h>
 #include <string.h>
 
 #include "base/file_path.h"
@@ skipping 55 matching lines @@
   // bundle dictionary.  It needs to look at the actual running .app's
   // Info.plist to access its LSUIElement property.
   NSDictionary* info_dictionary = [base::mac::MainBundle() infoDictionary];
   return [[info_dictionary objectForKey:@"LSUIElement"] boolValue] != NO;
 }
 
 FilePath PathForFrameworkBundleResource(CFStringRef resourceName) {
   NSBundle* bundle = base::mac::FrameworkBundle();
   NSString* resourcePath = [bundle pathForResource:(NSString*)resourceName
                                             ofType:nil];
-  if (!resourcePath)
-    return FilePath();
-  return FilePath([resourcePath fileSystemRepresentation]);
+  return NSStringToFilePath(resourcePath);
 }
 
 OSType CreatorCodeForCFBundleRef(CFBundleRef bundle) {
   OSType creator = kUnknownType;
   CFBundleGetPackageInfo(bundle, NULL, &creator);
   return creator;
 }
 
 OSType CreatorCodeForApplication() {
   CFBundleRef bundle = CFBundleGetMainBundle();
   if (!bundle)
     return kUnknownType;
 
   return CreatorCodeForCFBundleRef(bundle);
 }
 
 bool GetSearchPathDirectory(NSSearchPathDirectory directory,
                             NSSearchPathDomainMask domain_mask,
                             FilePath* result) {
   DCHECK(result);
   NSArray* dirs =
       NSSearchPathForDirectoriesInDomains(directory, domain_mask, YES);
   if ([dirs count] < 1) {
     return false;
   }
-  NSString* path = [dirs objectAtIndex:0];
-  *result = FilePath([path fileSystemRepresentation]);
+  *result = NSStringToFilePath([dirs objectAtIndex:0]);
   return true;
 }
 
 bool GetLocalDirectory(NSSearchPathDirectory directory, FilePath* result) {
   return GetSearchPathDirectory(directory, NSLocalDomainMask, result);
 }
 
 bool GetUserDirectory(NSSearchPathDirectory directory, FilePath* result) {
   return GetSearchPathDirectory(directory, NSUserDomainMask, result);
 }
@@ skipping 207 matching lines @@
       CFCopyTypeIDDescription(CFGetTypeID(value)));
   return "Expected value for key " +
       base::SysCFStringRefToUTF8(key) +
       " to be " +
       expected_type +
       " but it was " +
       base::SysCFStringRefToUTF8(actual_type_ref) +
       " instead";
 }
 
+NSString* FilePathToNSString(const FilePath& path) {
+  if (path.empty())
+    return nil;
+  return [[NSFileManager defaultManager]
+      stringWithFileSystemRepresentation:path.value().c_str()

[Mark Mentovai, 2012/02/08 04:29:04]

This is overkill. +[NSString stringWithUTF8String:] is fine. The reason is that
the filesystem representation is always UTF-8. Since it’s a stricter subset of
UTF-8, you can’t get a filesystem representation with -[NSString UTF8String] and
need to use -[NSString fileSystemEncoding], but to go the other way,
+stringWithUTF8String: will accept any UTF-8 including the specific UTF-8 of the
filesystem encoding. It is cheaper and more direct.

[sail, 2012/02/08 05:21:38]

Done.

+                                  length:path.value().size()];
+}
+
+FilePath NSStringToFilePath(NSString* str) {
+  if (!str || ![str length])

[Mark Mentovai, 2012/02/08 04:29:04]

You can simplify this to (![str length]).

[sail, 2012/02/08 05:21:38]

Done.

+    return FilePath();
+  return FilePath([str fileSystemRepresentation]);
+}
+
 }  // namespace mac
 }  // namespace base
 
 std::ostream& operator<<(std::ostream& o, const CFStringRef string) {
   return o << base::SysCFStringRefToUTF8(string);
 }
 
 std::ostream& operator<<(std::ostream& o, const CFErrorRef err) {
   base::mac::ScopedCFTypeRef<CFStringRef> desc(CFErrorCopyDescription(err));
   base::mac::ScopedCFTypeRef<CFDictionaryRef> user_info(
       CFErrorCopyUserInfo(err));
   CFStringRef errorDesc = NULL;
   if (user_info.get()) {
     errorDesc = reinterpret_cast<CFStringRef>(
         CFDictionaryGetValue(user_info.get(), kCFErrorDescriptionKey));
   }
   o << "Code: " << CFErrorGetCode(err)
     << " Domain: " << CFErrorGetDomain(err)
     << " Desc: " << desc.get();
   if(errorDesc) {
     o << "(" << errorDesc << ")";
   }
   return o;
 }