Publish app shortcuts on Mac

chrome/browser/web_applications/web_app_mac.mm

+// Copyright (c) 2012 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import <Cocoa/Cocoa.h>
+
+#include "chrome/browser/web_applications/web_app.h"
+
+#include "base/file_util.h"
+#include "base/mac/bundle_locations.h"
+#include "base/mac/foundation_util.h"
+#include "base/scoped_temp_dir.h"
+#include "base/sys_string_conversions.h"
+#include "chrome/common/mac/app_mode_common.h"
+#include "grit/chromium_strings.h"
+#include "ui/base/l10n/l10n_util_mac.h"
+
+namespace {
+
+FilePath GetAppLoaderPath() {
+  NSString* app_loader = [l10n_util::GetNSString(IDS_PRODUCT_NAME)
+      stringByAppendingString:@" App Mode Loader.app"];

[jeremy, 2012/02/07 08:29:27]

This CL is based on top of the temporary CL I sent you, right? Because the code
in the tree currently doesn't generate a .app for the loader.

[sail, 2012/02/07 18:17:06]

Yea, currently this code will fail but it should be ok to checkin since
everything is behind a flag.

+  return base::mac::PathForFrameworkBundleResource((CFStringRef)app_loader);
+}
+
+NSString* FilePathToNSString(const FilePath& file_path) {

[jeremy, 2012/02/07 08:29:27]

Can this live somewhere in base/mac/ ? I've got an in-flight cl that uses this
as well...

[sail, 2012/02/07 18:17:06]

Done.

+  return [[NSFileManager defaultManager]
+      stringWithFileSystemRepresentation:file_path.value().c_str()
+                                  length:file_path.value().size()];
+}
+
+bool IsWritable(const FilePath& path) {
+  return [[NSFileManager defaultManager] isWritableFileAtPath:
+      FilePathToNSString(path)];
+}
+
+FilePath GetDstPath() {
+  FilePath path;
+  if (base::mac::GetLocalDirectory(NSApplicationDirectory, &path) &&
+      IsWritable(path)) {
+    return path;
+  }
+
+  if (base::mac::GetUserDirectory(NSApplicationDirectory, &path))
+    return path;
+
+  return FilePath();
+}
+
+bool UpdatePlist(const FilePath& app_path,
+                 const ShellIntegration::ShortcutInfo& info) {
+  NSString* plist_path =
+      FilePathToNSString(app_path.Append("Contents").Append("Info.plist"));
+  NSMutableDictionary* dict =
+      [NSMutableDictionary dictionaryWithContentsOfFile:plist_path];
+
+  [dict setObject:base::SysUTF8ToNSString(info.extension_id)
+           forKey:app_mode::kCrAppModeShortcutIDKey];
+  [dict setObject:base::SysUTF16ToNSString(info.title)
+           forKey:app_mode::kCrAppModeShortcutNameKey];
+  [dict setObject:base::SysUTF8ToNSString(info.url.spec())
+           forKey:app_mode::kCrAppModeShortcutURLKey];
+  return [dict writeToFile:plist_path atomically:NO];
+}
+
+bool UpdateIcon() {
+  // TODO:(sail) Need to implement this.
+  return true;
+}
+
+}  // namespace
+
+namespace web_app {
+
+namespace internals {
+
+void CreateShortcutTask(const FilePath& web_app_path,
+                        const FilePath& profile_path,
+                        const ShellIntegration::ShortcutInfo& shortcut_info) {
+  FilePath app_name = GetSanitizedFileName(shortcut_info.title);
+  FilePath app_file_name = app_name.ReplaceExtension("app");
+  ScopedTempDir scoped_temp_dir;
+  if (!scoped_temp_dir.CreateUniqueTempDir())
+    return;
+  FilePath staging_path = scoped_temp_dir.path().Append(app_file_name);
+
+  // Update the app's plist and icon in a temp directory. This works around
+  // a Finder bug where the app's icon doesn't properly update.
+  if (!file_util::CopyDirectory(GetAppLoaderPath(), staging_path, true)) {
+    LOG(ERROR) << "Copying app to staging path: " << staging_path.value()
+               << " failed";
+    return;
+  }
+
+  if (!UpdatePlist(staging_path, shortcut_info))
+    return;
+
+  if (!UpdateIcon())
+    return;
+
+  FilePath dst_path = GetDstPath().Append(app_file_name);
+  if (!file_util::CopyDirectory(staging_path, dst_path, true)) {
+    LOG(ERROR) << "Copying app to dst path: " << dst_path.value() << " failed";
+    return;
+  }
+
+  [[NSWorkspace sharedWorkspace]
+                    selectFile:FilePathToNSString(dst_path)
+      inFileViewerRootedAtPath:nil];
+}
+
+}  // namespace internals
+
+}  // namespace web_app