One-click install for the OSX App Launcher

ui/app_list/cocoa/apps_search_results_model_bridge.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/app_list/cocoa/apps_search_results_model_bridge.h"
 
 #import <Cocoa/Cocoa.h>
 
 #include "base/strings/sys_string_conversions.h"
 #include "ui/app_list/app_list_model.h"
 #import "ui/app_list/cocoa/apps_search_results_controller.h"
 #include "ui/app_list/search_result.h"
 #include "ui/app_list/search_result_observer.h"
+#import "ui/base/cocoa/controls/blue_label_button.h"
 #import "ui/base/cocoa/menu_controller.h"
 
+namespace {
+
+// Padding on the left and right of action buttons.
+const CGFloat kActionButtonPadding = 10;
+
+}
+
+// Action target for all the action buttons on a result row.
+@interface ActionButtonTarget : NSObject {
+ @private
+  app_list::AppsSearchResultsModelBridge::ItemObserver* parent_;
+}
+
+// Designated initializer.
+- (id)initWithParent:
+    (app_list::AppsSearchResultsModelBridge::ItemObserver*)parent;
+
+// |sender| is the NSButton for the action.
+- (void)onActionButtonClicked:(id)sender;
+
+@end
+
 namespace app_list {
 
 class AppsSearchResultsModelBridge::ItemObserver : public SearchResultObserver {
  public:
   ItemObserver(AppsSearchResultsModelBridge* bridge, size_t index)
       : bridge_(bridge), row_in_view_(index) {
     // Cache the result, because the results array is updated before notifying
     // observers (which happens before deleting the SearchResult).
     result_ = [bridge_->parent_ results]->GetItemAt(index);
+    OnActionsChanged();
     result_->AddObserver(this);
   }
 
   virtual ~ItemObserver() {
     result_->RemoveObserver(this);
+    [action_button_ removeFromSuperview];
+    [action_button_ setTarget:nil];
   }
 
   NSMenu* GetContextMenu() {
     if (!context_menu_controller_) {
       ui::MenuModel* menu_model = result_->GetContextMenuModel();
       if (!menu_model)
         return nil;
 
       context_menu_controller_.reset(
           [[MenuController alloc] initWithModel:menu_model
                          useWithPopUpButtonCell:NO]);
     }
     return [context_menu_controller_ menu];
   }
 
+  CGFloat GetActionButtonWidth() {
+    CGFloat width = NSWidth([action_button_ bounds]);
+    if (width != 0)
+      width += kActionButtonPadding;
+    return width;
+  }
+
+  void InvokeActionAtIndex(int action_index) {
+    [[bridge_->parent_ delegate] invokeResultAction:result_
+                                            atIndex:action_index];
+  }
+
   // SearchResultObserver overrides:
   virtual void OnIconChanged() OVERRIDE {
     bridge_->ReloadDataForItems(row_in_view_, 1);
   }
-  virtual void OnActionsChanged() OVERRIDE {}
+  virtual void OnActionsChanged() OVERRIDE;
   virtual void OnIsInstallingChanged() OVERRIDE {}
   virtual void OnPercentDownloadedChanged() OVERRIDE {}
   virtual void OnItemInstalled() OVERRIDE {}
   virtual void OnItemUninstalled() OVERRIDE;
 
  private:
   AppsSearchResultsModelBridge* bridge_;  // Weak. Owns us.
   SearchResult* result_;  // Weak. Owned by AppListModel::SearchResults.
   size_t row_in_view_;
+  base::scoped_nsobject<ActionButtonTarget> action_target_;
+  base::scoped_nsobject<NSButton> action_button_;
   base::scoped_nsobject<MenuController> context_menu_controller_;
 
   DISALLOW_COPY_AND_ASSIGN(ItemObserver);
 };
 
 void AppsSearchResultsModelBridge::ItemObserver::OnItemUninstalled() {
   // Performing the search again will destroy |this|, so post a task. This also
   // ensures that the AppSearchProvider has observed the uninstall before
   // performing the search again, otherwise it will provide a NULL result.
   [[bridge_->parent_ delegate] performSelector:@selector(redoSearch)
                                     withObject:nil
                                     afterDelay:0];
 }
 
+void AppsSearchResultsModelBridge::ItemObserver::OnActionsChanged() {
+  [action_button_ removeFromSuperview];
+  action_button_.reset();
+  const SearchResult::Actions& actions = result_->actions();
+  if (actions.empty())
+    return;
+
+  size_t action_index = 0;
+  const SearchResult::Action& action = actions[action_index];
+  if (action.label_text.empty() || actions.size() != 1) {
+    // TODO(tapted) Support multiple action buttons.
+    NOTIMPLEMENTED();
+    return;
+  }
+
+  if (!action_target_)
+    action_target_.reset([[ActionButtonTarget alloc] initWithParent:this]);
+
+  action_button_.reset([[BlueLabelButton alloc] initWithFrame:NSZeroRect]);
+  [action_button_ setTitle:base::SysUTF16ToNSString(action.label_text)];
+  [action_button_ setTarget:action_target_];
+  [action_button_ setAction:@selector(onActionButtonClicked:)];
+  [action_button_ setTag:action_index];
+  [action_button_ sizeToFit];
+  NSRect button_frame = [action_button_ frame];
+  NSRect cell_frame =
+      [[bridge_->parent_ tableView] frameOfCellAtColumn:0
+                                                    row:row_in_view_];
+  NSPoint origin = NSMakePoint(
+      NSWidth(cell_frame) - NSWidth(button_frame) - kActionButtonPadding,
+      ceil(NSMidY(cell_frame) - NSMidY(button_frame)));
+  [action_button_ setFrameOrigin:origin];
+  [[bridge_->parent_ tableView] addSubview:action_button_];
+}
+
 AppsSearchResultsModelBridge::AppsSearchResultsModelBridge(
     AppsSearchResultsController* results_controller)
     : parent_(results_controller) {
   UpdateItemObservers();
   [parent_ results]->AddObserver(this);
 }
 
 AppsSearchResultsModelBridge::~AppsSearchResultsModelBridge() {
   [parent_ results]->RemoveObserver(this);
 }
 
 NSMenu* AppsSearchResultsModelBridge::MenuForItem(size_t index) {
   DCHECK_LT(index, item_observers_.size());
   return item_observers_[index]->GetContextMenu();
 }
 
+CGFloat AppsSearchResultsModelBridge::ActionButtonWidthForItem(size_t index) {
+  DCHECK_LT(index, item_observers_.size());
+  return item_observers_[index]->GetActionButtonWidth();
+}
+
 void AppsSearchResultsModelBridge::UpdateItemObservers() {
   DCHECK(item_observers_.empty());
   const size_t itemCount = [parent_ results]->item_count();
   for (size_t i = 0 ; i < itemCount; ++i)
     item_observers_.push_back(new ItemObserver(this, i));
 }
 
 void AppsSearchResultsModelBridge::ReloadDataForItems(
     size_t start, size_t count) const {
   NSIndexSet* column = [NSIndexSet indexSetWithIndex:0];
@@ skipping 29 matching lines @@
 }
 
 void AppsSearchResultsModelBridge::ListItemsChanged(
     size_t start, size_t count) {
   item_observers_.clear();
   ReloadDataForItems(start, count);
   UpdateItemObservers();
 }
 
 }  // namespace app_list
+
+@implementation ActionButtonTarget
+
+- (id)initWithParent:
+    (app_list::AppsSearchResultsModelBridge::ItemObserver*)parent {
+  if ((self = [super init])) {
+    parent_ = parent;
+  }
+  return self;
+}
+
+- (void)onActionButtonClicked:(id)sender {
+  parent_->InvokeActionAtIndex([sender tag]);
+}
+
+@end