Implemented BluetoothAdapterMac::AddDevices().

device/bluetooth/bluetooth_adapter_mac_unittest.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
+#import <IOBluetooth/IOBluetoothUtilities.h>
+#import <IOBluetooth/objc/IOBluetoothDevice.h>
+
 #include "base/memory/ref_counted.h"
 #include "base/test/test_simple_task_runner.h"
+#include "device/bluetooth/bluetooth_adapter.h"
 #include "device/bluetooth/bluetooth_adapter_mac.h"
 #include "testing/gtest/include/gtest/gtest.h"
 
+@interface TestIOBluetoothDevice : IOBluetoothDevice {
+ @private
+  NSString* _name;

[Mark Mentovai, 2013/03/19 19:14:20]

This doesn’t follow the Chromium convention of using a trailing underscore.

(Permission to use a leading underscore is new in the Objective-C guide, but
when working with existing projects like Chromium that have a long-established
tradition of using a trailing underscore, you should follow the local
convention.)

[youngki, 2013/03/20 18:48:27]

Done.

+  NSString* _address;
+}
+
++ (TestIOBluetoothDevice*)deviceWithName:(NSString*)name
+                                 address:(NSString*)address;
+- (id)initWithName:(NSString*)name address:(NSString*)address;
+
+@property (copy) NSString* name;

[Mark Mentovai, 2013/03/19 19:14:20]

You don’t need either property to be atomic, right? You can declare them both
nonatomic.

[youngki, 2013/03/20 18:48:27]

Putting nonatomic here throws an error:

error: 'atomic' attribute on property 'name' does not match the property
inherited from 'IOBluetoothDevice'

This property in IOBluetoothDevice is defined as:

@property(readonly, copy) NSString *name;

I think I should keep this atomic since that's what the parent class defined
it.. But I put nonatomic to address.

[Mark Mentovai, 2013/03/20 19:01:16]

youngki wrote:
Well, since you’re just a test class here, you could either

 - not inherit from IOBluetoothDevice (do you need to? maybe if you need some of
IOBluetoothDevice’s functionality, you could have an IOBluetoothDevice instance
variable)

or

 - choose different names, like testName and testAddress.

[youngki, 2013/03/20 20:30:50]

Done. This has to be IOBluetoothDevice instance, so I chose different names.

+@property (copy) NSString* address;
+
+@end
+
+@implementation TestIOBluetoothDevice
+
+@synthesize name = _name;
+@synthesize address = _address;
+
++ (TestIOBluetoothDevice*)deviceWithName:(NSString*)name
+                                 address:(NSString*)address {
+  return [[[TestIOBluetoothDevice alloc] initWithName:name
+                                              address:address] autorelease];
+}
+
+- (id)initWithName:(NSString*)name address:(NSString*)address {
+  if (self = [super init]) {
+    [self setName:name];
+    [self setAddress:address];
+  }
+
+  return self;
+}
+
+- (void)dealloc {
+  [self setName:nil];
+  [self setAddress:nil];
+  [super dealloc];
+}
+
+- (NSString*)addressString {
+  return [self address];
+}
+
+@end
+
+namespace {
+
+class AdapterObserver : public device::BluetoothAdapter::Observer {
+ public:
+  AdapterObserver() {
+    Clear();
+  }
+
+  void Clear() {
+    num_device_added_ = 0;
+    num_device_changed_ = 0;
+  }
+
+  virtual void DeviceAdded(
+      device::BluetoothAdapter* adapter,
+      device::BluetoothDevice* device) OVERRIDE {
+    num_device_added_++;
+  }
+
+  virtual void DeviceChanged(
+      device::BluetoothAdapter* adapter,
+      device::BluetoothDevice* device) OVERRIDE {
+    num_device_changed_++;
+  }
+
+  int num_device_added() const {
+    return num_device_added_;
+  }
+
+  int num_device_changed() const {
+    return num_device_changed_;
+  }
+
+ private:
+  int num_device_added_;
+  int num_device_changed_;
+};
+
+}  // namespace
+
 namespace device {
 
 class BluetoothAdapterMacTest : public testing::Test {
  public:
   BluetoothAdapterMacTest()
       : ui_task_runner_(new base::TestSimpleTaskRunner()),
         adapter_(new BluetoothAdapterMac()),
         adapter_mac_(static_cast<BluetoothAdapterMac*>(adapter_.get())) {
     adapter_mac_->TrackTestAdapter(ui_task_runner_);
+    adapter_observer_.Clear();
   }
 
   virtual void SetUp() OVERRIDE {
+    adapter_mac_->AddObserver(&adapter_observer_);
   }
 
   virtual void TearDown() OVERRIDE {
+    adapter_mac_->RemoveObserver(&adapter_observer_);
+  }
+
+  void UpdateDevices(NSArray* devices) {
+    adapter_mac_->UpdateDevices(devices);
   }
 
  protected:
   scoped_refptr<base::TestSimpleTaskRunner> ui_task_runner_;
   scoped_refptr<BluetoothAdapter> adapter_;
   BluetoothAdapterMac* adapter_mac_;
+  AdapterObserver adapter_observer_;
 };
 
 TEST_F(BluetoothAdapterMacTest, Poll) {
   EXPECT_FALSE(ui_task_runner_->GetPendingTasks().empty());
 }
 
+TEST_F(BluetoothAdapterMacTest, UpdateDevices) {
+  TestIOBluetoothDevice* android_device =
+      [TestIOBluetoothDevice deviceWithName:@"android"
+                                    address:@"11:22:33:44:55:66"];
+  TestIOBluetoothDevice* laptop_device =
+      [TestIOBluetoothDevice deviceWithName:@"laptop"
+                                    address:@"77:88:99:aa:bb:cc"];
+  TestIOBluetoothDevice* iphone_device =
+      [TestIOBluetoothDevice deviceWithName:@"iphone"
+                                    address:@"dd:ee:ff:11:22:33"];
+  NSMutableArray* devices = [NSMutableArray arrayWithCapacity:3];
+  [devices addObject:android_device];
+  [devices addObject:laptop_device];
+  [devices addObject:iphone_device];
+  UpdateDevices(devices);
+  EXPECT_EQ(3, adapter_observer_.num_device_added());
+  adapter_observer_.Clear();
+
+  UpdateDevices(devices);
+  EXPECT_EQ(0, adapter_observer_.num_device_added());
+  EXPECT_EQ(0, adapter_observer_.num_device_changed());
+
+  [iphone_device setName:@"apple phone"];
+  UpdateDevices(devices);
+  EXPECT_EQ(0, adapter_observer_.num_device_added());
+  EXPECT_EQ(1, adapter_observer_.num_device_changed());
+  adapter_observer_.Clear();
+}
+
 }  // namespace device