Implemented BluetoothAdapterMac::AddDevices().

device/bluetooth/bluetooth_adapter_mac.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "device/bluetooth/bluetooth_adapter_mac.h"
 
-#include <IOBluetooth/objc/IOBluetoothHostController.h>
+#import <IOBluetooth/objc/IOBluetoothDevice.h>
+#import <IOBluetooth/objc/IOBluetoothHostController.h>
 
 #include <string>
 
 #include "base/bind.h"
 #include "base/compiler_specific.h"
+#include "base/hash_tables.h"
 #include "base/location.h"
 #include "base/sequenced_task_runner.h"
 #include "base/single_thread_task_runner.h"
 #include "base/thread_task_runner_handle.h"
 #include "base/time.h"
 #include "base/strings/sys_string_conversions.h"
+#include "device/bluetooth/bluetooth_device_mac.h"
 
 // Replicate specific 10.7 SDK declarations for building with prior SDKs.
 #if !defined(MAC_OS_X_VERSION_10_7) || \
 MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_7
 
 @interface IOBluetoothHostController (LionSDKDeclarations)
 - (NSString *)nameAsString;
 - (BluetoothHCIPowerState)powerState;
 @end
 
@@ skipping 97 matching lines @@
   if (was_present != is_present) {
     FOR_EACH_OBSERVER(BluetoothAdapter::Observer, observers_,
                       AdapterPresentChanged(this, is_present));
   }
   if (powered_ != powered) {
     powered_ = powered;
     FOR_EACH_OBSERVER(BluetoothAdapter::Observer, observers_,
                       AdapterPoweredChanged(this, powered_));
   }
 
+  NSArray* paired_devices = [IOBluetoothDevice pairedDevices];
+  UpdateDevices(paired_devices);
+  RemoveUnpairedDevices(paired_devices);
+
   ui_task_runner_->PostDelayedTask(
       FROM_HERE,
       base::Bind(&BluetoothAdapterMac::PollAdapter,
                  weak_ptr_factory_.GetWeakPtr()),
       base::TimeDelta::FromMilliseconds(kPollIntervalMs));
 }
 
+void BluetoothAdapterMac::UpdateDevices(NSArray* devices) {
+  for (IOBluetoothDevice* device in devices) {
+    std::string device_address =
+        base::SysNSStringToUTF8([device addressString]);
+    DevicesMap::iterator found_device_iter = devices_.find(device_address);
+
+    if (found_device_iter == devices_.end()) {
+      devices_[device_address] = new BluetoothDeviceMac(device);
+      FOR_EACH_OBSERVER(BluetoothAdapter::Observer, observers_,
+                        DeviceAdded(this, devices_[device_address]));
+      continue;
+    }
+    BluetoothDeviceMac* device_mac =
+        static_cast<BluetoothDeviceMac*>(found_device_iter->second);
+    if (device_mac->device_fingerprint() !=
+        BluetoothDeviceMac::ComputeDeviceFingerprint(device)) {
+      devices_[device_address] = new BluetoothDeviceMac(device);
+      FOR_EACH_OBSERVER(BluetoothAdapter::Observer, observers_,
+                        DeviceChanged(this, devices_[device_address]));
+      delete device_mac;
+      continue;
+    }
+    if (!device_mac->IsVisible()) {
+      device_mac->SetVisible(true);
+      FOR_EACH_OBSERVER(BluetoothAdapter::Observer, observers_,
+                        DeviceChanged(this, device_mac));
+    }
+  }
+}
+
+void BluetoothAdapterMac::RemoveUnpairedDevices(NSArray* paired_devices) {
+  base::hash_set<std::string> paired_device_address_list;
+  for (IOBluetoothDevice* device in paired_devices)

[Mark Mentovai, 2013/03/20 19:01:16]

Use {braces} when you’re controlling something that takes more than one line.

[youngki, 2013/03/20 20:30:50]

Done.

+    paired_device_address_list.insert(
+        base::SysNSStringToUTF8([device addressString]));
+
+  DevicesMap::iterator iter = devices_.begin();
+  while (iter != devices_.end()) {
+    DevicesMap::iterator device_iter = iter;
+    ++iter;
+
+    if (paired_device_address_list.find(device_iter->first) !=
+        paired_device_address_list.end())
+      continue;
+
+    if (device_iter->second->IsPaired()) {
+      FOR_EACH_OBSERVER(BluetoothAdapter::Observer, observers_,
+                        DeviceRemoved(this, device_iter->second));
+      delete device_iter->second;

[Mark Mentovai, 2013/03/20 19:01:16]

What if IsPaired was false?

[youngki, 2013/03/20 20:30:50]

We do nothing. I was going to reuse BluetoothDeviceMac::UpdateDevice() when we
discover devices that are not necessarily paired, so I did not want to assume
here that |devices_| only contains paired devices. The method removes devices
that used to be paired but are unpaired by the system.

I just revised the comments in bluetooth_adapter_mac.h since the comment was a
bit confusing..

+      devices_.erase(device_iter);
+    }
+  }
+}
+
 }  // namespace device