Implemented BluetoothServiceRecordMac with unittest.

device/bluetooth/bluetooth_service_record_mac.mm

Index: device/bluetooth/bluetooth_service_record_mac.mm
diff --git a/device/bluetooth/bluetooth_service_record_mac.mm b/device/bluetooth/bluetooth_service_record_mac.mm
new file mode 100644
index 0000000000000000000000000000000000000000..f0f62b7c77bb61e5c138ca058de8d4a519fe1b44
--- /dev/null
+++ b/device/bluetooth/bluetooth_service_record_mac.mm
@@ -0,0 +1,71 @@
+// Copyright 2013 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "device/bluetooth/bluetooth_service_record_mac.h"
+
+#import <IOBluetooth/Bluetooth.h>

[Mark Mentovai, 2013/03/11 22:38:48]

You #include C[++] headers and #import Objective-C headers. This one is a C
header.

[youngki, 2013/03/12 04:15:12]

Done.

+#import <IOBluetooth/objc/IOBluetoothDevice.h>
+#import <IOBluetooth/objc/IOBluetoothSDPDataElement.h>
+#import <IOBluetooth/objc/IOBluetoothSDPServiceRecord.h>
+#import <IOBluetooth/objc/IOBluetoothSDPUUID.h>
+#import <IOBluetooth/IOBluetoothUtilities.h>
+
+#include <string>
+
+#include "base/basictypes.h"
+#include "base/stringprintf.h"
+#include "base/strings/sys_string_conversions.h"
+
+namespace {
+
+const BluetoothSDPServiceAttributeID kServiceClassId = 1;
+
+void ExtractUuid(IOBluetoothSDPDataElement* service_class_data,
+                 std::string* uuid) {
+  NSArray* inner_elements = [service_class_data getArrayValue];
+  IOBluetoothSDPUUID* sdp_uuid = nil;
+  for (NSUInteger i = 0; i < [inner_elements count]; i++) {

[Mark Mentovai, 2013/03/11 22:38:48]

You can use fast enumeration:

  for (IOBluetoothSDPDataElement* inner_element in inner_elements) {

[youngki, 2013/03/12 04:15:12]

Done.

+    IOBluetoothSDPDataElement* inner_element =
+    [inner_elements objectAtIndex: i];

[Mark Mentovai, 2013/03/11 22:38:48]

Continuation lines should be indented by 4, but you’re going to be removing this
statement anyway so it’s moot.

[youngki, 2013/03/12 04:15:12]

Done.

+    if ([inner_element getTypeDescriptor] ==
+        kBluetoothSDPDataElementTypeUUID) {

[Mark Mentovai, 2013/03/11 22:38:48]

I believe this will fit on a single line.

[youngki, 2013/03/12 04:15:12]

Done.

+      sdp_uuid = [[inner_element getUUIDValue] getUUIDWithLength: 16];

[Mark Mentovai, 2013/03/11 22:38:48]

There is no space between the : and its argument. This occurs throughout the
change. Consult the examples throughout
http://google-styleguide.googlecode.com/svn/trunk/objcguide.xml .

[youngki, 2013/03/12 04:15:12]

Done.

+      break;
+    }
+  }
+  if (sdp_uuid != nil) {
+    const uint8* uuid_bytes = reinterpret_cast<const uint8*>([sdp_uuid bytes]);
+    *uuid = base::StringPrintf(
+        "%02x%02x%02x%02x-%02x%02x-%02x%02x-%02x%02x-%02x%02x%02x%02x%02x%02x",
+        uuid_bytes[0], uuid_bytes[1], uuid_bytes[2], uuid_bytes[3],
+        uuid_bytes[4], uuid_bytes[5], uuid_bytes[6], uuid_bytes[7],
+        uuid_bytes[8], uuid_bytes[9], uuid_bytes[10], uuid_bytes[11],
+        uuid_bytes[12], uuid_bytes[13], uuid_bytes[14], uuid_bytes[15]);
+  }
+}
+
+}
+
+namespace device {
+
+BluetoothServiceRecordMac::BluetoothServiceRecordMac(
+    IOBluetoothSDPServiceRecord* record) {
+  name_ = base::SysNSStringToUTF8([record getServiceName]);

[Mark Mentovai, 2013/03/11 22:38:48]

Please use initializer list format instead of initializing in the constructor
body.
http://google-styleguide.googlecode.com/svn/trunk/cppguide.xml?showone=Constr...

[youngki, 2013/03/12 04:15:12]

Done.

+  device_ = [record device];
+  address_ = base::SysNSStringToUTF8(IOBluetoothNSStringFromDeviceAddress(
+      [device_ getAddress]));
+
+  supports_rfcomm_ =
+      [record getRFCOMMChannelID: &rfcomm_channel_] == kIOReturnSuccess;
+
+  IOBluetoothSDPDataElement* service_class_data =
+      [record getAttributeDataElement: kServiceClassId];
+  if (service_class_data != nil &&

[Mark Mentovai, 2013/03/11 22:38:48]

You don’t need to check for nil. See
http://google-styleguide.googlecode.com/svn/trunk/objcguide.xml?showone=nil_C...
and
http://developer.apple.com/library/ios/documentation/cocoa/conceptual/Program...
.

[youngki, 2013/03/12 04:15:12]

Done.

+      [service_class_data getTypeDescriptor] ==
+          kBluetoothSDPDataElementTypeDataElementSequence) {
+    ExtractUuid(service_class_data, &uuid_);
+  }
+}
+
+}  // namespace device