Fixed dart2js.bat so it looks for dart2js snapshot in right place.

sdk/bin/dart2js.bat

 @echo off
 REM Copyright (c) 2012, the Dart project authors.  Please see the AUTHORS file
 REM for details. All rights reserved. Use of this source code is governed by a
 REM BSD-style license that can be found in the LICENSE file.
 
-set SCRIPTPATH=%~dp0
+setlocal
+setlocal enableextensions enabledelayedexpansion

[ahe, 2013/01/04 09:35:17]

I don't understand why you need "enabledelayedexpansion".  As far as I can tell,
you never change the value of EXTRA_VM_OPTIONS in a way where the % syntax
doesn't do the same.

enableextensions is needed because you call a label, I think.

[aam-me, 2013/01/04 13:44:59]

You are right! I don't need delayed expansion.

enableextensions enables several things that are used in the script: %%~dpi,
%%~fi syntax, as well !EXTRA_VM_OPTIONS! syntax(but not the delayed expansion
semantic which is separately enabled by enabledelatedexpansion).
But these extensions actually seems to be enabled by default, so I got rid of
that.

 
-REM Does the path have a trailing slash? If so, remove it.
-if %SCRIPTPATH:~-1%== set SCRIPTPATH=%SCRIPTPATH:~0,-1%
+rem Handle the case where dart-sdk/bin has been symlinked to.
+set DIR_NAME_WITH_SLASH=%~dp0
+set DIR_NAME=%DIR_NAME_WITH_SLASH:~0,-1%%
+call :follow_links "%DIR_NAME%", RETURNED_BIN_DIR
 
-set arguments=%*
-set SNAPSHOTNAME="%SCRIPTPATH%dart2js.snapshot"
-if exist %SNAPSHOTNAME% set SNAPSHOT=--use_script_snapshot=%SNAPSHOTNAME%
+rem Get rid of surrounding quotes.
+for %%i in ("%RETURNED_BIN_DIR%") do set BIN_DIR=%%~fi
 
-"%SCRIPTPATH%dart" --no_use_inlining --heap_growth_rate=512 %SNAPSHOT% "%SCRIPTPATH%..\lib\_internal\compiler\implementation\dart2js.dart" %arguments%
+rem Get absolute full name for SDK_DIR.
+for %%i in ("%BIN_DIR%\..\") do set SDK_DIR=%%~fi
+
+set DART2JS=%SDK_DIR%lib\_internal\compiler\implementation\dart2js.dart
+set DART=%BIN_DIR%\dart
+set SNAPSHOT=%DART2JS%.snapshot
+
+set EXTRA_OPTIONS=
+
+rem Let dart2js_developer.bat specify this one '--checked' vm option.
+if not _%EXTRA_VM_OPTIONS%_ == _--checked_ set EXTRA_VM_OPTIONS=
+
+if exist "%SNAPSHOT%" (
+  echo Using snapshot "%SNAPSHOT%" >&2
+  set EXTRA_VM_OPTIONS=!EXTRA_VM_OPTIONS! --use_script_snapshot="%SNAPSHOT%"
+)
+
+rem See comments regarding options below in dart2js shell script.
+set EXTRA_VM_OPTIONS=!EXTRA_VM_OPTIONS! --heap_growth_rate=512
+set EXTRA_VM_OPTIONS=!EXTRA_VM_OPTIONS! --no_use_inlining
+
+"%DART%" %EXTRA_VM_OPTIONS% "%DART2JS%" %EXTRA_OPTIONS% %*
+
+endlocal
+
+goto end
+
+:follow_links
+setlocal
+for %%i in (%1) do set result=%%~fi
+set current=
+for /f "tokens=2 delims=[]" %%i in ('dir /a:l ^"%~dp1^" 2^>nul ^

[ahe, 2013/01/04 09:35:17]

I don't understand this command. What is the output of dir /a:l?

I assume it is something like this:


...
\>     FILENAME [LINKS_TO]
...

Ignore the \ above, I added it to make sure the review tool didn't think it is a
quote.

[aam-me, 2013/01/04 13:44:59]

Yes, correct.

This is what dir /a:l output looks like:
===
C:\def ghi>dir /a:l \
 Volume in drive C has no label.
 Volume Serial Number is 9401-7D51

 Directory of C:\

01/03/2013  10:11 PM    <JUNCTION>     abc def
[c:\dart_bleeding\dart-repo.9\dart\build\ReleaseIA32\dart-sdk]
01/03/2013  10:56 PM    <JUNCTION>     def ghi
[c:\dart_bleeding\dart-repo.9\dart\build\ReleaseIA32\dart-sdk\bin]
===

So, what happens is that is that I'm looking for filename surrounded by right
angle bracket and left square bracket.

+                                     ^| find ">     %~n1 ["') do (

[ahe, 2013/01/04 09:35:17]

In Unix this would be:

 grep ">     ${NAME_OF_PARAMETER_1} ["

Right?

[aam-me, 2013/01/04 13:44:59]

Right!

+  set current=%%i
+)
+if not "%current%"=="" call :follow_links "%current%", result
+endlocal & set %~2=%result%
+goto :eof
+
+:end