Add error codes to iossim.

testing/iossim/iossim.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import <Foundation/Foundation.h>
 #include <asl.h>
 #include <libgen.h>
 #include <stdarg.h>
 #include <stdio.h>
 
@@ skipping 68 matching lines @@
 NSString* const kSimulatorRelativePath =
     @"Platforms/iPhoneSimulator.platform/Developer/Applications/"
     @"iPhone Simulator.app";
 
 // Simulator Error String Key. This can be found by looking in the Simulator's
 // Localizable.strings files.
 NSString* const kSimulatorAppQuitErrorKey = @"The simulated application quit.";
 
 const char* gToolName = "iossim";
 
+// Exit status codes.
+const int kExitSuccess = EXIT_SUCCESS;
+const int kExitFailure = EXIT_FAILURE;
+const int kExitInvalidArguments = 2;
+const int kExitInitializationFailure = 3;
+const int kExitAppFailedToStart = 4;
+const int kExitAppCrashed = 5;
+
 void LogError(NSString* format, ...) {
   va_list list;
   va_start(list, format);
 
   NSString* message =
       [[[NSString alloc] initWithFormat:format arguments:list] autorelease];
 
   fprintf(stderr, "%s: ERROR: %s\n", gToolName, [message UTF8String]);
   fflush(stderr);
 
@@ skipping 117 matching lines @@
       appRunning_ = NO;
       [self tailOutput];
       // Note that exiting in this state leaves a process running
       // (e.g. /.../iPhoneSimulator4.3.sdk/usr/libexec/installd -t 30) that will
       // prevent future simulator sessions from being started for 30 seconds
       // unless the iOS Simulator application is killed altogether.
       [self session:session didEndWithError:nil];
 
       // session:didEndWithError should not return (because it exits) so
       // the execution path should never get here.
-      exit(EXIT_FAILURE);
+      exit(kExitFailure);
     }
 
     LogError(@"Simulator failed to start: \"%@\" (%@:%ld)",
              [error localizedDescription],
              [error domain], static_cast<long int>([error code]));
-    exit(EXIT_FAILURE);
+    exit(kExitAppFailedToStart);
   }
 
   // Start a thread to write contents of outputPath to stdout.
   appRunning_ = YES;
   outputThread_ = [[NSThread alloc] initWithTarget:self
                                           selector:@selector(tailOutput)
                                             object:nil];
   [outputThread_ start];
 }
 
@@ skipping 18 matching lines @@
     NSString* ignorableErrorStr =
         [self localizedSimulatorErrorString:kSimulatorAppQuitErrorKey];
     if ([ignorableErrorStr isEqual:localizedDescription]) {
       LogWarning(@"Ignoring that Simulator ended with: \"%@\" (%@:%ld)",
                  localizedDescription, [error domain],
                  static_cast<long int>([error code]));
     } else {
       LogError(@"Simulator ended with error: \"%@\" (%@:%ld)",
                localizedDescription, [error domain],
                static_cast<long int>([error code]));
-      exit(EXIT_FAILURE);
+      exit(kExitFailure);
     }
   }
 
   // Check if the simulated app exited abnormally by looking for system log
   // messages from launchd that refer to the simulated app's PID. Limit query
   // to messages in the last minute since PIDs are cyclical.
   aslmsg query = asl_new(ASL_TYPE_QUERY);
   asl_set_query(query, ASL_KEY_SENDER, "launchd",
                 ASL_QUERY_OP_EQUAL | ASL_QUERY_OP_SUBSTRING);
   asl_set_query(query, ASL_KEY_REF_PID,
                 [[[session simulatedApplicationPID] stringValue] UTF8String],
                 ASL_QUERY_OP_EQUAL);
   asl_set_query(query, ASL_KEY_TIME, "-1m", ASL_QUERY_OP_GREATER_EQUAL);
 
   // Log any messages found.
   aslresponse response = asl_search(NULL, query);
   BOOL entryFound = NO;
   aslmsg entry;
   while ((entry = aslresponse_next(response)) != NULL) {
     entryFound = YES;
     LogWarning(@"Console message: %s", asl_get(entry, ASL_KEY_MSG));
   }
 
   // launchd only sends messages if the process crashed or exits with a
   // non-zero status, so if the query returned any results iossim should exit
   // with non-zero status.
   if (entryFound) {
     LogError(@"Simulated app crashed or exited with non-zero status");
-    exit(EXIT_FAILURE);
+    exit(kExitAppCrashed);
   }
-  exit(EXIT_SUCCESS);
+  exit(kExitSuccess);
 }
 @end
 
 namespace {
 
 // Finds the developer dir via xcode-select or the DEVELOPER_DIR environment
 // variable.
 NSString* FindDeveloperDir() {
   // Check the env first.
   NSDictionary* env = [[NSProcessInfo processInfo] environment];
@@ skipping 40 matching lines @@
   if (![simBundle load])
     return nil;
   return simBundle;
 }
 
 // Helper to find a class by name and die if it isn't found.
 Class FindClassByName(NSString* nameOfClass) {
   Class theClass = NSClassFromString(nameOfClass);
   if (!theClass) {
     LogError(@"Failed to find class %@ at runtime.", nameOfClass);
-    exit(EXIT_FAILURE);
+    exit(kExitInitializationFailure);
   }
   return theClass;
 }
 
 // Converts the given app path to an application spec, which requires an
 // absolute path.
 DTiPhoneSimulatorApplicationSpecifier* BuildAppSpec(NSString* appPath) {
   Class applicationSpecifierClass =
       FindClassByName(@"DTiPhoneSimulatorApplicationSpecifier");
   if (![appPath isAbsolutePath]) {
@@ skipping 195 matching lines @@
       case 'u':
         simHomePath = [[NSFileManager defaultManager]
             stringWithFileSystemRepresentation:optarg length:strlen(optarg)];
         break;
       case 'e': {
         NSString* envLine = [NSString stringWithUTF8String:optarg];
         NSRange range = [envLine rangeOfString:@"="];
         if (range.location == NSNotFound) {
           LogError(@"Invalid key=value argument for -e.");
           PrintUsage();
-          exit(EXIT_FAILURE);
+          exit(kExitInvalidArguments);
         }
         NSString* key = [envLine substringToIndex:range.location];
         NSString* value = [envLine substringFromIndex:(range.location + 1)];
         [appEnv setObject:value forKey:key];
       }
         break;
       case 't': {
         int timeout = atoi(optarg);
         if (timeout > 0) {
           sessionStartTimeout = static_cast<NSTimeInterval>(timeout);
         } else {
           LogError(@"Invalid startup timeout (%s).", optarg);
           PrintUsage();
-          exit(EXIT_FAILURE);
+          exit(kExitInvalidArguments);
         }
       }
         break;
       case 'h':
         PrintUsage();
-        exit(EXIT_SUCCESS);
+        exit(kExitSuccess);
       default:
         PrintUsage();
-        exit(EXIT_FAILURE);
+        exit(kExitInvalidArguments);
     }
   }
 
   // There should be at least one arg left, specifying the app path. Any
   // additional args are passed as arguments to the app.
   if (optind < argc) {
     appPath = [[NSFileManager defaultManager]
         stringWithFileSystemRepresentation:argv[optind]
                                     length:strlen(argv[optind])];
     appName = [appPath lastPathComponent];
     while (++optind < argc) {
       [appArgs addObject:[NSString stringWithUTF8String:argv[optind]]];
     }
   } else {
     LogError(@"Unable to parse command line arguments.");
     PrintUsage();
-    exit(EXIT_FAILURE);
+    exit(kExitInvalidArguments);
   }
 
   NSString* developerDir = FindDeveloperDir();
   if (!developerDir) {
     LogError(@"Unable to find developer directory.");
-    exit(EXIT_FAILURE);
+    exit(kExitInitializationFailure);
   }
 
   NSBundle* simulatorFramework = LoadSimulatorFramework(developerDir);
   if (!simulatorFramework) {
     LogError(@"Failed to load the Simulator Framework.");
-    exit(EXIT_FAILURE);
+    exit(kExitInitializationFailure);
   }
 
   // Make sure the app path provided is legit.
   DTiPhoneSimulatorApplicationSpecifier* appSpec = BuildAppSpec(appPath);
   if (!appSpec) {
     LogError(@"Invalid app path: %@", appPath);
-    exit(EXIT_FAILURE);
+    exit(kExitInitializationFailure);
   }
 
   // Make sure the SDK path provided is legit (or nil).
   DTiPhoneSimulatorSystemRoot* systemRoot = BuildSystemRoot(sdkVersion);
   if (!systemRoot) {
     LogError(@"Invalid SDK version: %@", sdkVersion);
-    exit(EXIT_FAILURE);
+    exit(kExitInitializationFailure);
   }
 
   // Get the paths for stdout and stderr so the simulated app's output will show
   // up in the caller's stdout/stderr.
   NSString* outputDir = CreateTempDirectory(@"iossim-XXXXXX");
   NSString* stdioPath = [outputDir stringByAppendingPathComponent:@"stdio.txt"];
 
   // Determine the deviceFamily based on the deviceName
   NSNumber* deviceFamily = nil;
   if (!deviceName || CaseInsensitivePrefixSearch(deviceName, @"iPhone")) {
     deviceFamily = [NSNumber numberWithInt:kIPhoneFamily];
   } else if (CaseInsensitivePrefixSearch(deviceName, @"iPad")) {
     deviceFamily = [NSNumber numberWithInt:kIPadFamily];
   } else {
     LogError(@"Invalid device name: %@. Must begin with 'iPhone' or 'iPad'",
              deviceName);
-    exit(EXIT_FAILURE);
+    exit(kExitInvalidArguments);
   }
 
   // Set up the user home directory for the simulator
   if (!simHomePath) {
     NSString* dirNameTemplate =
         [NSString stringWithFormat:@"iossim-%@-%@-XXXXXX", appName, deviceName];
     simHomePath = CreateTempDirectory(dirNameTemplate);
     if (!simHomePath) {
       LogError(@"Unable to create unique directory for template %@",
                dirNameTemplate);
-      exit(EXIT_FAILURE);
+      exit(kExitInitializationFailure);
     }
   }
   if (!InitializeSimulatorUserHome(simHomePath, deviceName)) {
     LogError(@"Unable to initialize home directory for simulator: %@",
              simHomePath);
-    exit(EXIT_FAILURE);
+    exit(kExitInitializationFailure);
   }
 
   // Create the config and simulator session.
   DTiPhoneSimulatorSessionConfig* config = BuildSessionConfig(appSpec,
                                                               systemRoot,
                                                               stdioPath,
                                                               stdioPath,
                                                               appArgs,
                                                               appEnv,
                                                               deviceFamily);
@@ skipping 15 matching lines @@
   } else {
     LogError(@"Simulator failed request to start:  \"%@\" (%@:%ld)",
              [error localizedDescription],
              [error domain], static_cast<long int>([error code]));
   }
 
   // Note that this code is only executed if the simulator fails to start
   // because once the main run loop is started, only the delegate calling
   // exit() will end the program.
   [pool drain];
-  return EXIT_FAILURE;
+  return kExitFailure;
 }