Cocoa: Media gallery dialog unit test

chrome/browser/ui/cocoa/extensions/media_galleries_dialog_cocoa_unittest.mm

Index: chrome/browser/ui/cocoa/extensions/media_galleries_dialog_cocoa_unittest.mm
diff --git a/chrome/browser/ui/cocoa/extensions/media_galleries_dialog_cocoa_unittest.mm b/chrome/browser/ui/cocoa/extensions/media_galleries_dialog_cocoa_unittest.mm
new file mode 100644
index 0000000000000000000000000000000000000000..707616b681d5e9b05454f617ebf2d3a641fc36b2
--- /dev/null
+++ b/chrome/browser/ui/cocoa/extensions/media_galleries_dialog_cocoa_unittest.mm
@@ -0,0 +1,102 @@
+// Copyright (c) 2012 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "base/gtest_prod_util.h"
+#include "chrome/browser/media_gallery/media_galleries_dialog_controller.h"
+#include "chrome/browser/ui/cocoa/extensions/media_galleries_dialog_cocoa.h"
+#include "testing/gtest/include/gtest/gtest.h"
+
+namespace chrome {
+
+class MediaGalleriesDialogTest : public testing::Test,
+                                 public MediaGalleriesDialogController {

[Nico, 2012/08/14 21:23:36]

It's confusing me that the test fixture class is a fake MGDController at the
same time. Could you separate them into two classes? (and if the MGDC fake is
doing similar things in the gtk test, possibly share it between the gtk and
cocoa tests)?

+ public:
+  MediaGalleriesDialogTest() : toggles_(0) {}
+  virtual ~MediaGalleriesDialogTest() {}
+
+  virtual void DialogFinished(bool accepted) OVERRIDE {}
+  virtual void DidToggleGallery(const MediaGalleryPrefInfo* pref_info,
+                                bool enabled) OVERRIDE {
+    toggles_++;
+    MediaGalleriesDialogController::DidToggleGallery(pref_info, enabled);
+  }
+
+ protected:
+  // Counter that tracks the number of times a checkbox has been toggled.
+  size_t toggles_;
+};
+
+// Tests that checkboxes are initialized according to the contents of
+// |known_galleries|.
+TEST_F(MediaGalleriesDialogTest, InitializeCheckboxes) {
+  MediaGalleryPrefInfo gallery1;
+  gallery1.device_id = "/a";
+  known_galleries_[1] = GalleryPermission(gallery1, true);
+  MediaGalleryPrefInfo gallery2;
+  gallery2.device_id = "/b";
+  known_galleries_[2] = GalleryPermission(gallery2, false);
+
+  scoped_ptr<MediaGalleriesDialogCocoa> dialog(
+      static_cast<MediaGalleriesDialogCocoa*>(
+          MediaGalleriesDialog::Create(this)));
+  EXPECT_EQ(2U, [dialog->checkboxes_ count]);
+
+  // Note that checkboxes_ is sorted from bottom up.
+  NSButton* checkbox1 = [dialog->checkboxes_ objectAtIndex:1];
+  EXPECT_EQ([checkbox1 state], NSOnState);
+
+  NSButton* checkbox2 = [dialog->checkboxes_ objectAtIndex:0];
+  EXPECT_EQ([checkbox2 state], NSOffState);
+
+  // Initializing checkboxes should not cause them to be toggled.
+  EXPECT_EQ(0U, toggles_);
+}
+
+// Tests that toggling checkboxes updates the controller.
+TEST_F(MediaGalleriesDialogTest, ToggleCheckboxes) {
+  MediaGalleryPrefInfo gallery1;
+  gallery1.pref_id = 1;
+  known_galleries_[1] = GalleryPermission(gallery1, true);
+
+  scoped_ptr<MediaGalleriesDialogCocoa> dialog(
+      static_cast<MediaGalleriesDialogCocoa*>(
+          MediaGalleriesDialog::Create(this)));
+  EXPECT_EQ(1U, [dialog->checkboxes_ count]);
+
+  NSButton* checkbox = [dialog->checkboxes_ objectAtIndex:0];
+  EXPECT_EQ([checkbox state], NSOnState);
+
+  [checkbox performClick:nil];
+  EXPECT_EQ([checkbox state], NSOffState);
+  [checkbox performClick:nil];
+  EXPECT_EQ([checkbox state], NSOnState);
+
+  EXPECT_EQ(2U, toggles_);
+}
+
+// Tests that UpdateGallery will add a new checkbox, but only if it refers to
+// a gallery that the dialog hasn't seen before.
+TEST_F(MediaGalleriesDialogTest, UpdateAdds) {
+  scoped_ptr<MediaGalleriesDialogCocoa> dialog(
+      static_cast<MediaGalleriesDialogCocoa*>(
+          MediaGalleriesDialog::Create(this)));
+
+  EXPECT_EQ(0U, [dialog->checkboxes_ count]);
+
+  MediaGalleryPrefInfo gallery1;
+  gallery1.device_id = "/a";
+  dialog->UpdateGallery(&gallery1, true);
+  EXPECT_EQ(1U, [dialog->checkboxes_ count]);
+
+  MediaGalleryPrefInfo gallery2;
+  gallery2.device_id = "/b";
+  dialog->UpdateGallery(&gallery2, true);
+  EXPECT_EQ(2U, [dialog->checkboxes_ count]);
+
+  dialog->UpdateGallery(&gallery2, false);
+  EXPECT_EQ(2U, [dialog->checkboxes_ count]);
+}
+
+
+}  // namespace chrome