A batch file to ease copying a build from a network share to a local machine for testing.

tools/win/copy-installer.bat

+ECHO OFF
+
+REM Copyright (c) 2012 The Chromium Authors. All rights reserved.
+REM Use of this source code is governed by a BSD-style license that can be
+REM found in the LICENSE file.
+
+REM Copies an installer and symbols from a build directory on a network share
+REM into the directory \[out|build]\[Debug|Release] on the current drive.

[gab, 2012/07/31 22:23:24]

nit: Replace [...|...] by (...|...)

(...|...) is the correct notation for a regex and given this very much looks
like one, might as well make it one :)!

[grt (UTC plus 2), 2012/08/01 08:10:30]

[foo|bar] is closer the convention for optional arguments in a command line
tool.

+REM
+REM Usage:
+REM   \\build.share\<path_to_checkout>\src\tools\win\copy-installer.bat
+REM 
+REM By default, the script will copy the Debug build in the tree, falling back
+REM to the Release build if one is not found.  Similarly, the ninja output
+REM directory is preferred over the devenv output directory.  Specify
+REM "out|build" and/or "Debug|Release" (case matters) to on the command line in

[gab, 2012/07/31 22:23:24]

nit: "to on the command line" -> "on the command line"?

[grt (UTC plus 2), 2012/08/01 08:10:30]

Done.

+REM any order to influence selection.  The defaults for build type and location
+REM can also be overridden in a given build tree by creating a
+REM "copy-installer.cfg" file alongside the .gclient file that sets the OUTPUT
+REM and/or FLAVOR variables.

[gab, 2012/07/31 22:23:24]

optional: I feel BUILDTYPE (which is something I intuitively know what it is)
would be better than FLAVOR (which is vague out of context).

[grt (UTC plus 2), 2012/08/01 08:10:30]

Done.

+REM
+REM Install Robocopy for superior performance on Windows XP if desired (it is
+REM present by default on Vista+).
+
+SETLOCAL
+
+REM Get the path to the build tree's src directory.
+CALL :_canonicalize "%~dp0..\.."
+SET FROM=%RET%
+
+REM Read local configuration (set OUTPUT and FLAVOR there).
+IF EXIST "%FROM%\..\copy-installer.cfg" CALL "%FROM%\..\copy-installer.cfg"
+
+REM Read OUTPUT and/or FLAVOR from command line.
+FOR %%a IN (%1 %2) do (
+IF "%%a"=="out" SET OUTPUT=out
+IF "%%a"=="build" SET OUTPUT=build
+IF "%%a"=="Debug" SET FLAVOR=Debug
+IF "%%a"=="Release" SET FLAVOR=Release
+)
+
+CALL :_find_build
+IF "%OUTPUT%%FLAVOR%"=="" (
+ECHO No build found to copy.
+EXIT 1
+)
+
+SET FROM=%FROM%\%OUTPUT%\%FLAVOR%
+SET TO=\%OUTPUT%\%FLAVOR%
+
+REM Figure out what files to copy based on the build type (shared/static).
+IF EXIST "%FROM%\base.dll" (
+SET TOCOPY=*.pdb setup.exe setup.exe.manifest chrome.packed.7z *.dll

[gab, 2012/07/31 22:23:24]

I would really like an option to NOT copy pdb's (I very rarely need them and
they are huge... I've only been copying them manually when I need them for now
(i.e. once every 25 copies or something...)).

[grt (UTC plus 2), 2012/08/01 08:10:30]

patches welcome.  :-)

[gab, 2012/08/01 20:14:37]

ok ok..!

I guess it's not that bad given robocopy only copies the diffs anyways so that
you don't constantly pay the overhead (although chrome.pdb is HUGE, especially
in static builds... which are guess are not as relevant now as they used to
be...)

+SET INSTALLER=setup.exe
+) ELSE (
+SET TOCOPY=*.pdb mini_installer.exe
+SET INSTALLER=mini_installer.exe
+)
+
+REM Branch to handle copying via robocopy (fast) or xcopy (slow).

[gab, 2012/07/31 22:23:24]

As *.dll is so big what I do is only copy the files that got updated after an
incremental build.

The easy technical solution is probably to only copy the files from the FROM
side which are more recent than the most recent file on the TO side.

Note: We probably also want an option for a clean copy (but I'm totally fine if
that's just manually deleting the TO directory).

[grt (UTC plus 2), 2012/08/01 08:10:30]

robocopy skips files that haven't changed.

[gab, 2012/08/01 20:14:37]

Oh :)! Awesome!

+robocopy /? 1> nul 2> nul
+IF "%ERRORLEVEL%"=="9009" GOTO _xcopy else GOTO _robocopy
+
+REM robocopy is rsync, basically.
+:_robocopy
+robocopy "%FROM%" "%TO%" %TOCOPY% /J /MT
+GOTO _copydone
+
+REM xcopy is not.
+:_xcopy
+IF NOT exist "%TO%" mkdir "%TO%"
+call :_xcopy_hack %TOCOPY%
+GOTO _copydone
+
+:_copydone
+ECHO Ready to run/debug %TO%\%INSTALLER%.
+GOTO :EOF
+
+REM All labels henceforth are subroutines intended to be invoked by CALL.
+
+REM Search for a mini_installer.exe in the candidate build outputs.
+:_find_build
+IF "%OUTPUT%"=="" (
+SET OUTPUTS=out build
+) ELSE (
+SET OUTPUTS=%OUTPUT%
+SET OUTPUT=
+)
+
+IF "%FLAVOR%"=="" (
+SET FLAVORS=Debug Release
+) ELSE (
+SET FLAVORS=%FLAVOR%
+SET FLAVOR=
+)
+
+FOR %%o IN (%OUTPUTS%) DO (
+FOR %%f IN (%FLAVORS%) DO (
+IF EXIST "%FROM%\%%o\%%f\mini_installer.exe" (
+SET OUTPUT=%%o
+SET FLAVOR=%%f
+GOTO :EOF
+)
+)
+)
+GOTO :EOF
+
+REM We can't use a for..in..do loop since we have wildcards, so we make a call
+REM to this with the files to copy.
+:_xcopy_hack
+SHIFT
+IF "%0"=="" GOTO :EOF
+xcopy "%FROM%\%0" "%TO%" /y
+GOTO _xcopy_hack
+
+REM Canonicalize the first argument, returning it in RET.
+:_canonicalize
+SET RET=%~f1
+GOTO :EOF