A batch file to ease copying a build from a network share to a local machine for testing.

tools/win/copy-installer.bat

+ECHO OFF
+
+REM Copyright (c) 2012 The Chromium Authors. All rights reserved.
+REM Use of this source code is governed by a BSD-style license that can be
+REM found in the LICENSE file.
+
+REM Copies an installer and symbols from a build directory on a network share
+REM into the directory \[out|build]\[Debug|Release] on the current drive.
+REM
+REM Usage:
+REM   \\build.share\src\chrome\tools\win\copy-installer.bat

[robertshield, 2012/07/31 14:05:59]

is this under src\chrome\tools\win or src\tools\win? rietveld makes it look like
the latter.

[grt (UTC plus 2), 2012/07/31 14:19:43]

Yeah, the latter.  That's what I get for trying to shorten the path to one of my
checkouts.  I'll change it to
"\\build.share\...\src\tools\win\copy-installer.bat".  Does that seem clear
enough to you?

[robertshield, 2012/07/31 16:28:06]

Yep, although I would suggest "..." -> "<path_to_checkout> or some such, lest
"..." be read as ".."

+REM 
+REM By default, the script will copy the Debug build in the tree, falling back
+REM to the Release build if one is not found.  Similarly, the ninja output
+REM directory is preferred over the devenv output directory.  Specify
+REM "out|build" and/or "Debug|Release" (case matters) to on the command line in
+REM any order to influence selection.  The defaults for build type and location
+REM can also be overridden in a given build tree by creating a
+REM "copy-installer.cfg" file alongside the .gclient file that sets the OUTPUT
+REM and/or FLAVOR variables.

[robertshield, 2012/07/31 14:05:59]

Mention that this uses robocopy if available, recommend installing robocopy.

[grt (UTC plus 2), 2012/07/31 14:19:43]

Robocopy is included with Vista+.  Does this affect your request?  xcopy is good
enough that I think it's probably a waste of time to suggest to XP users that
they should figure out how to get/install robocopy.  wdyt?

[robertshield, 2012/07/31 16:28:06]

SGTM

+
+SETLOCAL
+
+REM Get the path to the build tree's src directory.
+CALL :_canonicalize "%~dp0..\.."
+SET FROM=%RET%
+
+REM Read local configuration (set OUTPUT and FLAVOR there).
+IF EXIST "%FROM%\..\copy-installer.cfg" CALL "%FROM%\..\copy-installer.cfg"
+
+REM Read OUTPUT and/or FLAVOR from command line.
+FOR %%a IN (%1 %2) do (
+IF "%%a"=="out" SET OUTPUT=out
+IF "%%a"=="build" SET OUTPUT=build
+IF "%%a"=="Debug" SET FLAVOR=Debug
+IF "%%a"=="Release" SET FLAVOR=Release
+)
+
+CALL :_find_build
+IF "%OUTPUT%%FLAVOR%"=="" (
+ECHO No build found to copy.
+EXIT 1
+)
+
+SET FROM=%FROM%\%OUTPUT%\%FLAVOR%
+SET TO=\%OUTPUT%\%FLAVOR%
+
+REM Figure out what files to copy based on the build type (shared/static).
+IF EXIST "%FROM%\base.dll" (
+SET TOCOPY=*.pdb setup.exe setup.exe.manifest chrome.packed.7z *.dll
+SET INSTALLER=setup.exe
+) ELSE (
+SET TOCOPY=*.pdb mini_installer.exe
+SET INSTALLER=mini_installer.exe
+)
+
+REM Branch to handle copying via robocopy (fast) or xcopy (slow).
+robocopy /? 1> nul 2> nul
+IF "%ERRORLEVEL%"=="9009" GOTO _xcopy else GOTO _robocopy
+
+REM robocopy is rsync, basically.
+:_robocopy
+robocopy "%FROM%" "%TO%" %TOCOPY% /J /MT
+GOTO _copydone
+
+REM xcopy is not.
+:_xcopy
+IF NOT exist "%TO%" mkdir "%TO%"
+call :_xcopy_hack %TOCOPY%
+GOTO _copydone
+
+:_copydone
+ECHO Ready to run/debug %TO%\%INSTALLER%.
+GOTO :EOF
+
+REM All labels henceforth are subroutines intended to be invoked by CALL.
+
+REM Search for a mini_installer.exe in the candidate build outputs.
+:_find_build
+IF "%OUTPUT%"=="" (
+SET OUTPUTS=out build
+) ELSE (
+SET OUTPUTS=%OUTPUT%
+SET OUTPUT=
+)
+
+IF "%FLAVOR%"=="" (
+SET FLAVORS=Debug Release
+) ELSE (
+SET FLAVORS=%FLAVOR%
+SET FLAVOR=
+)
+
+FOR %%o IN (%OUTPUTS%) DO (
+FOR %%f IN (%FLAVORS%) DO (
+IF EXIST "%FROM%\%%o\%%f\mini_installer.exe" (
+SET OUTPUT=%%o
+SET FLAVOR=%%f
+GOTO :EOF
+)
+)
+)
+GOTO :EOF
+
+REM We can't use a for..in..do loop since we have wildcards, so we make a call
+REM to this with the files to copy.
+:_xcopy_hack
+SHIFT
+IF "%0"=="" GOTO :EOF
+xcopy "%FROM%\%0" "%TO%" /y
+GOTO _xcopy_hack
+
+REM Canonicalize the first argument, returning it in RET.
+:_canonicalize
+SET RET=%~f1
+GOTO :EOF