OLD | NEW |
(Empty) | |
| 1 # wcwidth.m4 serial 14 |
| 2 dnl Copyright (C) 2006-2008 Free Software Foundation, Inc. |
| 3 dnl This file is free software; the Free Software Foundation |
| 4 dnl gives unlimited permission to copy and/or distribute it, |
| 5 dnl with or without modifications, as long as this notice is preserved. |
| 6 |
| 7 AC_DEFUN([gl_FUNC_WCWIDTH], |
| 8 [ |
| 9 AC_REQUIRE([gl_WCHAR_H_DEFAULTS]) |
| 10 |
| 11 dnl Persuade glibc <wchar.h> to declare wcwidth(). |
| 12 AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS]) |
| 13 |
| 14 AC_REQUIRE([gt_TYPE_WCHAR_T]) |
| 15 AC_REQUIRE([gt_TYPE_WINT_T]) |
| 16 |
| 17 AC_CHECK_HEADERS_ONCE([wchar.h]) |
| 18 AC_CHECK_FUNCS_ONCE([wcwidth]) |
| 19 |
| 20 AC_CHECK_DECLS([wcwidth], [], [], [ |
| 21 /* AIX 3.2.5 declares wcwidth in <string.h>. */ |
| 22 #include <string.h> |
| 23 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before |
| 24 <wchar.h>. |
| 25 BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included |
| 26 before <wchar.h>. */ |
| 27 #include <stddef.h> |
| 28 #include <stdio.h> |
| 29 #include <time.h> |
| 30 #include <wchar.h> |
| 31 ]) |
| 32 if test $ac_cv_have_decl_wcwidth != yes; then |
| 33 HAVE_DECL_WCWIDTH=0 |
| 34 fi |
| 35 |
| 36 if test $ac_cv_func_wcwidth = no; then |
| 37 REPLACE_WCWIDTH=1 |
| 38 else |
| 39 dnl On MacOS X 10.3, wcwidth(0x0301) (COMBINING ACUTE ACCENT) returns 1. |
| 40 dnl On OSF/1 5.1, wcwidth(0x200B) (ZERO WIDTH SPACE) returns 1. |
| 41 dnl This leads to bugs in 'ls' (coreutils). |
| 42 AC_CACHE_CHECK([whether wcwidth works reasonably in UTF-8 locales], |
| 43 [gl_cv_func_wcwidth_works], |
| 44 [ |
| 45 AC_TRY_RUN([ |
| 46 #include <locale.h> |
| 47 /* AIX 3.2.5 declares wcwidth in <string.h>. */ |
| 48 #include <string.h> |
| 49 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before |
| 50 <wchar.h>. |
| 51 BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included |
| 52 before <wchar.h>. */ |
| 53 #include <stddef.h> |
| 54 #include <stdio.h> |
| 55 #include <time.h> |
| 56 #include <wchar.h> |
| 57 #if !HAVE_DECL_WCWIDTH |
| 58 extern |
| 59 # ifdef __cplusplus |
| 60 "C" |
| 61 # endif |
| 62 int wcwidth (int); |
| 63 #endif |
| 64 int main () |
| 65 { |
| 66 if (setlocale (LC_ALL, "fr_FR.UTF-8") != NULL) |
| 67 if (wcwidth (0x0301) > 0 || wcwidth (0x200B) > 0) |
| 68 return 1; |
| 69 return 0; |
| 70 }], [gl_cv_func_wcwidth_works=yes], [gl_cv_func_wcwidth_works=no], |
| 71 [gl_cv_func_wcwidth_works="guessing no"]) |
| 72 ]) |
| 73 case "$gl_cv_func_wcwidth_works" in |
| 74 *yes) ;; |
| 75 *no) REPLACE_WCWIDTH=1 ;; |
| 76 esac |
| 77 fi |
| 78 if test $REPLACE_WCWIDTH = 1; then |
| 79 AC_LIBOBJ([wcwidth]) |
| 80 fi |
| 81 |
| 82 if test $REPLACE_WCWIDTH = 1 || test $HAVE_DECL_WCWIDTH = 0; then |
| 83 gl_REPLACE_WCHAR_H |
| 84 fi |
| 85 ]) |
OLD | NEW |