OLD | NEW |
(Empty) | |
| 1 # warnings.m4 serial 2 |
| 2 dnl Copyright (C) 2008 Free Software Foundation, Inc. |
| 3 dnl This file is free software; the Free Software Foundation |
| 4 dnl gives unlimited permission to copy and/or distribute it, |
| 5 dnl with or without modifications, as long as this notice is preserved. |
| 6 |
| 7 dnl From Simon Josefsson |
| 8 |
| 9 # gl_AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH]) |
| 10 # ---------------------------------------------------- |
| 11 # Provide the functionality of AS_VAR_IF if Autoconf does not have it. |
| 12 m4_ifdef([AS_VAR_IF], |
| 13 [m4_copy([AS_VAR_IF], [gl_AS_VAR_IF])], |
| 14 [m4_define([gl_AS_VAR_IF], |
| 15 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])]) |
| 16 |
| 17 # gl_AS_VAR_APPEND(VAR, VALUE) |
| 18 # ---------------------------- |
| 19 # Provide the functionality of AS_VAR_APPEND if Autoconf does not have it. |
| 20 m4_ifdef([AS_VAR_APPEND], |
| 21 [m4_copy([AS_VAR_APPEND], [gl_AS_VAR_APPEND])], |
| 22 [m4_define([gl_AS_VAR_APPEND], |
| 23 [AS_VAR_SET([$1], [AS_VAR_GET([$1])$2])])]) |
| 24 |
| 25 # gl_WARN_ADD(PARAMETER, [VARIABLE = WARN_CFLAGS]) |
| 26 # ------------------------------------------------ |
| 27 # Adds parameter to WARN_CFLAGS if the compiler supports it. For example, |
| 28 # gl_WARN_ADD([-Wparentheses]). |
| 29 AC_DEFUN([gl_WARN_ADD], |
| 30 [AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_$1])dnl |
| 31 AC_CACHE_CHECK([whether compiler handles $1], [gl_Warn], [ |
| 32 save_CPPFLAGS="$CPPFLAGS" |
| 33 CPPFLAGS="${CPPFLAGS} $1" |
| 34 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([])], |
| 35 [AS_VAR_SET([gl_Warn], [yes])], |
| 36 [AS_VAR_SET([gl_Warn], [no])]) |
| 37 CPPFLAGS="$save_CPPFLAGS" |
| 38 ]) |
| 39 AS_VAR_PUSHDEF([gl_Flags], m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]))dnl |
| 40 gl_AS_VAR_IF([gl_Warn], [yes], [gl_AS_VAR_APPEND([gl_Flags], [" $1"])]) |
| 41 AS_VAR_POPDEF([gl_Flags])dnl |
| 42 AS_VAR_POPDEF([gl_Warn])dnl |
| 43 m4_ifval([$2], [AS_LITERAL_IF([$2], [AC_SUBST([$2])], [])])dnl |
| 44 ]) |
OLD | NEW |