OLD | NEW |
(Empty) | |
| 1 # -*- Autoconf -*- |
| 2 # Sanity-test a C++ compiler. |
| 3 # |
| 4 # Copyright (C) 2004, 2006 Free Software Foundation, Inc. |
| 5 # |
| 6 # This program is free software: you can redistribute it and/or modify |
| 7 # it under the terms of the GNU General Public License as published by |
| 8 # the Free Software Foundation, either version 3 of the License, or |
| 9 # (at your option) any later version. |
| 10 # |
| 11 # This program is distributed in the hope that it will be useful, |
| 12 # but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 # GNU General Public License for more details. |
| 15 # |
| 16 # You should have received a copy of the GNU General Public License |
| 17 # along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 18 |
| 19 # Written by Paul Eggert. |
| 20 |
| 21 AC_DEFUN([BISON_TEST_FOR_WORKING_CXX_COMPILER], |
| 22 [ |
| 23 AC_CACHE_CHECK([whether $CXX builds executables that work], |
| 24 bison_cv_cxx_works, |
| 25 [AC_LANG_PUSH([C++]) |
| 26 bison_cv_cxx_works=no |
| 27 AC_COMPILE_IFELSE( |
| 28 [AC_LANG_PROGRAM( |
| 29 [#include <cstdlib> |
| 30 #include <iostream> |
| 31 #include <map> |
| 32 #include <string> |
| 33 using namespace std;], |
| 34 [std::cerr << ""; |
| 35 cout << ""; |
| 36 typedef std::pair<unsigned int, int> uipair; |
| 37 std::map<unsigned int, int> m; |
| 38 std::map<unsigned int, int>::iterator i; |
| 39 m.insert (uipair (4, -4)); |
| 40 for (i = m.begin (); i != m.end (); ++i) |
| 41 if (i->first != 4) |
| 42 return 1;])], |
| 43 [AS_IF([AC_TRY_COMMAND([$CXX -o conftest$ac_exeext $CXXFLAGS $CPPFLAGS $LD
FLAGS conftest.$ac_objext $LIBS >&AS_MESSAGE_LOG_FD])], |
| 44 [AS_IF([test "$cross_compiling" = yes], |
| 45 [bison_cv_cxx_works=cross], |
| 46 [AS_IF([AC_TRY_COMMAND(./conftest$ac_exeext)], |
| 47 [bison_cv_cxx_works=yes])])]) |
| 48 rm -f conftest$ac_exeext]) |
| 49 AC_LANG_POP([C++])]) |
| 50 |
| 51 case $bison_cv_cxx_works in |
| 52 yes) |
| 53 BISON_CXX_WORKS=':';; |
| 54 no | cross) |
| 55 BISON_CXX_WORKS='exit 77';; |
| 56 esac |
| 57 |
| 58 AC_SUBST([BISON_CXX_WORKS]) |
| 59 AM_CONDITIONAL(BISON_CXX_WORKS, test $bison_cv_cxx_works = yes) |
| 60 ]) |
OLD | NEW |